media-gfx/solvespace-9999-r1.ebuild

solvespace-9999-r1.ebuild (text/plain), 1.66 KB, created by mehw on 2020-07-26 11:56:46 UTC

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

CMAKE_MIN_VERSION=3.7.2

inherit cmake-utils xdg-utils git-r3

DESCRIPTION="Parametric 2d/3d CAD"
HOMEPAGE="https://solvespace.com"
EGIT_REPO_URI="https://github.com/solvespace/${PN}.git"
EGIT_SUBMODULES=( 'extlib/libdxfrw' 'extlib/flatbuffers' 'extlib/q3d' 'extlib/mimalloc' )

LICENSE="GPL-3"
SLOT="0"
KEYWORDS=""
IUSE="coverage debug gtk openmp spacenav test"

DEPEND="sys-libs/zlib
	media-libs/libpng
	media-libs/freetype:2
	x11-libs/cairo
	x11-libs/pixman
	coverage? ( dev-util/lcov )
	gtk? (
		virtual/glu
		media-libs/glew
		media-libs/fontconfig:1.0
		dev-libs/json-c
		dev-cpp/gtkmm:3.0
		dev-cpp/pangomm:1.4
	)
	spacenav? ( dev-libs/libspnav )"
RDEPEND="${DEPEND}"
BDEPEND="virtual/pkgconfig
	sys-devel/gettext"

REQUIRED_USE="coverage? ( debug )
	spacenav? ( gtk )"

HTML_DOCS=()
DOCS=( CHANGELOG.md CONTRIBUTING.md README.md THIRD_PARTIES.txt )

pkg_setup() {
	if [[ "$(tc-get-compiler-type)" == "gcc" ]]; then
		if [[ $(gcc-major-version) -lt 5 ]]; then
			die "GCC 5.0+ is required"
		fi
	fi
	if use openmp && [[ ${MERGE_TYPE} != binary ]]; then
		tc-has-openmp || die "Please switch to an openmp compatible compiler"
	fi
}

src_configure() {
	CMAKE_BUILD_TYPE="$(usex debug Debug Release)"
	local mycmakeargs=(
		-DENABLE_COVERAGE=$(usex coverage)
		-DENABLE_GUI=$(usex gtk)
		-DENABLE_OPENMP=$(usex openmp)
		-DENABLE_TESTS=$(usex test)
	)
	cmake-utils_src_configure
}

pkg_postinst() {
	xdg_icon_cache_update
	xdg_desktop_database_update
	xdg_mimeinfo_database_update
}

pkg_postrm() {
	xdg_icon_cache_update
	xdg_desktop_database_update
	xdg_mimeinfo_database_update
}