media-gfx/fotoxx-maps-1.4.ebuild

fotoxx-maps-1.4.ebuild (text/plain), 1.14 KB, created by mehw on 2020-07-19 12:04:22 UTC

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit xdg-utils

DESCRIPTION="Map files for media-gfx/fotoxx"
HOMEPAGE="https://www.kornelix.net/fotoxx/fotoxx.html"
SRC_URI="https://kornelix.net/downloads/downloads/${P}.tar.gz"

LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

# For install instruction read doc/README.

# To avoid circular dependency, do not depend on media-gfx/fotoxx,
# since that package already depends on media-gfx/fotoxx-maps once
# its 'map' use flag is enabled.
DEPEND=""
RDEPEND="${DEPEND}"

S="${WORKDIR}/${PN}"
PATCHES=(
	"${FILESDIR}"/${P}-binary.patch
	"${FILESDIR}"/${P}-documentation.patch
)

DOCS=()
HTML_DOCS=()

src_install() {
	# For the Help menu items to work, *.html must be in /usr/share/doc/${PF},
	# and README, changelog, translations, edit-menus, KB-shortcuts must not be compressed
	emake DESTDIR="${D}" install
	rm -f "${D}"/usr/share/doc/${PF}/*.man || die
	docompress -x /usr/share/doc
}

pkg_postinst() {
	xdg_desktop_database_update
	xdg_mimeinfo_database_update
}

pkg_postrm() {
	xdg_desktop_database_update
	xdg_mimeinfo_database_update
}