Ebuild for Outreach Project Tool MAX (OPT_1.2.6_MAX)

outreach-1.2.6.ebuild (text/plain), 1.43 KB, created by Gunnar Wrobel (RETIRED) on 2005-08-01 11:53:42 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils webapp

MY_PV=${PV//./-}
DESCRIPTION="Outreach Project Tool (OPT) is a PHP general-purpose virtual commonplace for customers and \
			developers to collaborate in developing projects."
HOMEPAGE="http://outreach.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/OPT_${MY_PV}_MAX.tar.gz"

LICENSE=""
IUSE=""
KEYWORDS="~x86"

RDEPEND="virtual/php
         dev-php/jpgraph
         media-fonts/corefonts
         dev-db/mysql"

S=${WORKDIR}/OPT_${MY_PV}_MAX

src_unpack() {
	unpack ${A}
	cd ${S}/opt

	epatch ${FILESDIR}/gentoo-jpgraph.patch

	cd ..
}

src_install() {
	webapp_src_preinst

	DOCS="CHANGES INSTALL README docs/*"

	# Do documentation
	for docfile in ${DOCS}
	do
	  dodoc ${docfile}
	done

	# Copy files to destination
	cp -R opt/* ${D}/${MY_HTDOCSDIR}

	# Remove documentation
	for docfile in ${DOCS}
	do
	  rm -rf ${D}/${MY_HTDOCSDIR}/${docfile}
	done

	# Remove libraries
	rm -rf ${D}/${MY_HTDOCSDIR}/include/jpgraph
	rm -rf ${D}/${MY_HTDOCSDIR}/include/horde

	# Change permissions for web-based setup
	for srvown in include/setup_lock include/OPT_lib.php include/mail_retrieve.pl include/cvs_parse.pl
	do
	  touch ${D}${MY_HTDOCSDIR}/${srvown}
	  webapp_serverowned ${MY_HTDOCSDIR}/${srvown}
	done
		
	# Post install 
	webapp_postinst_txt en ${FILESDIR}/postinstall-en.txt
							

	webapp_src_install
}