[patch] diffutils-3.7-r1.ebuild

0001-sys-apps-diffutils-EAPI-7-bump.patch (text/plain), 1.97 KB, created by David Michael on 2020-07-10 20:34:20 UTC

From 657260ab73d5c2e14cf782ae1d5452817b74b313 Mon Sep 17 00:00:00 2001
From: David Michael <[e-mail]>
Date: Fri, 10 Jul 2020 16:31:57 -0400
Subject: [PATCH] sys-apps/diffutils: EAPI 7 bump

Closes: https://bugs.gentoo.org/732114
Package-Manager: Portage-2.3.99, Repoman-2.3.23
Signed-off-by: David Michael <[e-mail]>
---
 sys-apps/diffutils/diffutils-3.7-r1.ebuild | 43 ++++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 sys-apps/diffutils/diffutils-3.7-r1.ebuild

diff --git a/sys-apps/diffutils/diffutils-3.7-r1.ebuild b/sys-apps/diffutils/diffutils-3.7-r1.ebuild
new file mode 100644
index 00000000000..692b8fd3cc7
--- /dev/null
+++ b/sys-apps/diffutils/diffutils-3.7-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic
+
+DESCRIPTION="Tools to make diffs and compare files"
+HOMEPAGE="https://www.gnu.org/software/diffutils/"
+SRC_URI="mirror://gnu/diffutils/${P}.tar.xz
+	mirror://gnu-alpha/diffutils/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="nls static"
+
+BDEPEND="nls? ( sys-devel/gettext )"
+
+DOCS=( AUTHORS ChangeLog NEWS README THANKS TODO )
+
+src_configure() {
+	use static && append-ldflags -static
+
+	# Disable automagic dependency over libsigsegv; see bug #312351.
+	export ac_cv_libsigsegv=no
+
+	# required for >=glibc-2.26, bug #653914
+	use elibc_glibc && export gl_cv_func_getopt_gnu=yes
+
+	local myeconfargs=(
+		--with-packager="Gentoo"
+		--with-packager-version="${PVR}"
+		--with-packager-bug-reports="https://bugs.gentoo.org/"
+		$(use_enable nls)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	# explicitly allow parallel testing
+	emake check
+}
-- 
2.26.2