app-cdr/nero/nero-2.0.0.2.ebuild

nero-2.0.0.2.ebuild (text/plain), 1.89 KB, created by Oliver Knitterscheidt on 2005-07-27 16:43:22 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-cdr/nero/nero-2.0.0.2.ebuild,v 1.4 2005/07/28 01:13:02 oknitter Exp $

inherit eutils rpm

NERO_RPM="nerolinux-2.0.0.2-x86.rpm"
NERO_FETCH_URL="http://www.nero.com/en/NeroLINUX.html"

DESCRIPTION="Nero Burning ROM for Linux"
HOMEPAGE="http://www.nero.com/"
SRC_URI="${NERO_RPM}"
LICENSE="Nero"
SLOT="0"
KEYWORDS="~x86"
IUSE="mp3 oggvorbis shorten"
DEPEND=""
RDEPEND="virtual/libc
	virtual/x11
	>=x11-libs/gtk+-1.2
	>=dev-libs/glib-1.2
	mp3? ( media-sound/mpg123 )
	oggvorbis? ( media-sound/vorbis-tools )
	shorten? ( media-sound/shorten )"
RESTRICT="fetch nostrip"

pkg_nofetch() {
	einfo "Please download ${NERO_RPM}"
	einfo "from ${NERO_FETCH_URL}"
	einfo "and move it to ${DISTDIR}"
	ewarn "You have to register a valid Nero 6 serial number with the"
	ewarn "above mentioned web site to be able to download the file."
	ewarn "Also, the program will only work in demo mode for a"
	ewarn "certain period of time without a valid Nero 6 serial number"
}

src_unpack() {
	if [ ! -r "${DISTDIR}/${NERO_RPM}" ]; then
		die "Cannot read ${DISTDIR}/${NERO_RPM}. Please check the permissions and try again."
	fi
	cd "${WORKDIR}"
	rpm_src_unpack
}

src_compile() { :; }

src_install() {
	cd "${WORKDIR}"

	dodir /usr/share/nero
	insinto /usr/share/nero
	doins ./usr/share/nero/{*.so,DosBootImage.ima,Nero.txt,CDROM.CFG}

	dodir /usr/share/nero/desktop
	insinto /usr/share/nero/desktop
	doins ./usr/share/nero/desktop/NeroLINUX.template

	dodir /usr/share/nero/docs
	insinto /usr/share/nero/docs
	doins ./usr/share/nero/docs/{Manual.pdf,EULA}

	dodir /usr/share/nero/pixmaps
	insinto /usr/share/nero/pixmaps
	doins ./usr/share/nero/pixmaps/nero.png

	dodir /usr/lib
	insinto /usr/lib
	doins ./usr/lib/*.so

	dobin ./usr/bin/nero

	insinto /usr/share/applications
	doins "${FILESDIR}/nero.desktop"
}