sys-apps/suspend2-userui-0.5.1.ebuild

suspend2-userui-0.5.1.ebuild (text/plain), 1.21 KB, created by Laurento Frittella (mrfree) on 2005-07-18 02:14:58 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit toolchain-funcs

DESCRIPTION="Software Suspend 2 User Interface"

HOMEPAGE="http://www.suspend2.net"
SRC_URI="http://www.suspend2.net/downloads/all/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"

IUSE="fbsplash"

DEPEND="sys-apps/sed"
RDEPEND="fbsplash? ( media-gfx/splashutils
					sys-libs/zlib
					media-libs/libpng
					media-libs/jpeg )"

src_compile() {
	emake CC="$(tc-getCC)" CFLAGS="${CFLAGS}" suspend2ui_text \
		|| die "emake userui_text failed"

	if use fbsplash; then
		emake CC="$(tc-getCC)" CFLAGS="${CFLAGS} -I. -I/usr/include/freetype2/" fbsplash \
			|| die "emake fbsplash failed"
		emake CC="$(tc-getCC)" CFLAGS="${CFLAGS}" suspend2ui_fbsplash \
			|| die "emake userui_fbsplash failed"
	fi
}

src_install() {
	dosbin suspend2ui_text
	use fbsplash && dosbin suspend2ui_fbsplash

	dodoc ChangeLog KERNEL_API README TODO USERUI_API
}

pkg_postinst() {
	if use fbsplash; then
		einfo
		einfo "You must create a symlink from /etc/splash/suspend2"
		einfo "to the theme you want userui_fbsplash to use, e.g.:"
		einfo
		einfo "ln -s /etc/splash/emergence /etc/splash/suspend2"
		einfo
	fi
}