# Copyright 1999-2020 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=6

inherit cmake-utils eutils fdo-mime

DESCRIPTION="Main UI of synfig: Film-Quality Vector Animation"
HOMEPAGE="http://www.synfig.org/"
SRC_URI="https://github.com/synfig/synfig/archive/v${PV}.tar.gz -> synfig-${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

DEPEND="
	dev-cpp/gtkmm:3.0
	dev-cpp/libxmlpp:2.6
	dev-libs/libsigc++:2
	>=media-gfx/synfig-${PV}
	media-libs/mlt"
RDEPEND=${DEPEND}

S=${WORKDIR}/synfig-${PV}/synfig-studio

src_prepare() {
	sed -i "/DESTINATION/s/lib/$(get_libdir)/" src/synfigapp/CMakeLists.txt
	sed -i '/pkg_check_modules(LIBXML REQUIRED libxml++-2.6)/ a\pkg_check_modules(MLT REQUIRED mlt++)' src/CMakeLists.txt
	sed -i '/include(workarearenderer\/CMakeLists.txt)/ a\\ntarget_include_directories(synfigstudio PRIVATE ${MLT_INCLUDE_DIRS})' src/gui/CMakeLists.txt
	sed -i '/${Gettext_LIBRARIES}/ a\    ${MLT_LIBRARIES}\n    ${LIBXML_LIBRARIES}' src/gui/CMakeLists.txt
	eapply_user
}

src_configure() {
	local mycmakeargs=(
		-DCMAKE_BUILD_TYPE=Release
	)
	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile build_images all
}

src_install() {
	cmake-utils_src_install

	doicon ${BUILD_DIR}/images/synfig_icon.png
	make_desktop_entry "synfigstudio" "Synfig Studio" "/usr/share/pixmaps/synfig_icon.png" "AudioVideo"
}

pkg_postinst() {
	fdo-mime_mime_database_update
}

pkg_postrm() {
	fdo-mime_mime_database_update
}