# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

PYTHON_COMPAT=( python3_{6,7} )

inherit meson python-r1 udev

DESCRIPTION="Library to configure gaming mice"
HOMEPAGE="https://github.com/libratbag/libratbag"
SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc elogind systemd test"
REQUIRED_USE="?? ( systemd elogind ) ${PYTHON_REQUIRED_USE}"

DEPEND="
	${PYTHON_DEPS}
	virtual/pkgconfig
	doc? ( app-doc/doxygen )
	elogind? ( sys-auth/elogind )
	systemd? ( sys-apps/systemd )
	dev-python/python-evdev[${PYTHON_USEDEP}]
	dev-lang/swig
	test? ( dev-util/valgrind )
"
RDEPEND="
	dev-libs/libevdev
	virtual/libudev
"

src_prepare() {
	default

	sed '/default:/d' -i meson_options.txt || die
	eapply "${FILESDIR}"/${PN}-systemd.patch
}

src_configure() {
	python_setup

	local emesonargs=(
		-Dsystemd=$(usex systemd true $(usex elogind true false))
		-Dlogind-provider=$(usex elogind elogind systemd)
		-Ddocumentation=$(usex doc true false)
		-Dtests=$(usex test true false)
		-Dudev-dir=$(get_udevdir)
	)

	meson_src_configure
}