ebuild for version 4.3.0

linux-gpib-modules-4.3.0.ebuild (text/plain), 1.30 KB, created by Manuel Mommertz on 2020-04-09 12:03:09 UTC

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit linux-info linux-mod autotools toolchain-funcs

DESCRIPTION="Kernel modules for GPIB (IEEE 488.2) hardware"
HOMEPAGE="https://linux-gpib.sourceforge.io/"
SRC_URI="mirror://sourceforge/linux-gpib/linux-gpib-${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="isa debug"

COMMONDEPEND=""
RDEPEND="${COMMONDEPEND}
	!<sci-libs/linux-gpib-4.2.0_rc1
"
DEPEND="${COMMONDEPEND}
	virtual/pkgconfig"

S=${WORKDIR}/linux-gpib-kernel-${PV}

pkg_setup() {
	linux-mod_pkg_setup

	if kernel_is -lt 2 6 8; then
		die "Kernel versions older than 2.6.8 are not supported."
	fi
}

src_unpack() {
	default
	unpack "${WORKDIR}/linux-gpib-${PV}/linux-gpib-kernel-${PV}.tar.gz"
}

src_compile() {
	set_arch_to_kernel
	emake \
		DESTDIR="${D}" \
		INSTALL_MOD_PATH="${D}" \
		docdir=/usr/share/doc/${PF}/html \
		LINUX_SRCDIR=${KV_DIR} \
		$(usex isa 'ENABLE_ISA="yes"' '') \
		$(usex debug 'GPIB_DEBUG=1' '')
}

src_install() {
	set_arch_to_kernel
	emake \
		DESTDIR="${D}" \
		INSTALL_MOD_PATH="${D}" \
		DEPMOD="/bin/true" \
		docdir=/usr/share/doc/${PF}/html install

	dodoc ChangeLog AUTHORS README* NEWS
}

pkg_preinst() {
	linux-mod_pkg_preinst
	enewgroup gpib
}

pkg_postinst() {
	linux-mod_pkg_postinst
}