# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils java-pkg

DESCRIPTION="a free, open source ontology editor and knowledge-base framework"
HOMEPAGE="http://protege.stanford.edu/"
SRC_URI="http://protege.stanford.edu/download/prerelease/protege-src-3.1.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="doc jikes"

DEPEND=">=virtual/jdk-1.4
		dev-java/javacc
		dev-java/ant
		jikes? ( dev-java/jikes )
		dev-java/junit
		=dev-java/jgoodies-looks-bin-1.2*"
RDEPEND=">=virtual/jre-1.4"

S=${WORKDIR}/Protege\ 3.1\ Beta

src_unpack() {
	unpack ${A}
	cd "${S}"
	echo "javacc.home=/usr/share/javacc" > local.properties
	sed -i \
		-e "s:{javacc.home}/bin/lib:{javacc.home}/lib:" \
		-e "s:unicode_panel.jar:unicode.jar:" \
		-e "s:looks.jar:jgoodies-looks-bin.jar:" \
		build.xml \
		|| die "fixing build.xml failed"
	epatch ${FILESDIR}/${P}-Formatter.patch # otherwise fails with 1.5
	cd "${S}/lib"
	rm -f *.jar
	java-pkg_jar-from junit
	java-pkg_jar-from unicode-bin
	java-pkg_jar-from jgoodies-looks-bin
}

src_compile() {
	local antflags="jar"
	use doc && antflags="${antflags} javadocs"
	use jikes && antflags="${antflags} -Dbuild.compiler=jikes"
	ant ${antflags} || die "compilation failed"
}

src_install() {
	java-pkg_dojar dist/${PN}.jar
	echo "java -jar /usr/share/protege/lib/protege.jar" > protege
	dobin protege
	use doc && java-pkg_dohtml -r docs/*
	#use source && java-pkg_dosrc dist/protege-src-3.1.zip
}