entropy_rsa ebuild

entropy_rsa-0.9.0.431.ebuild (text/plain), 3.10 KB, created by michael on 2005-07-03 21:38:07 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

MY_PV_BUILD=${PV/*.}
MY_PV=${PV/.${MY_PV_BUILD}}
DESCRIPTION="A p2p-node to share your files, infos, philosophy ... anonymously"
HOMEPAGE="http://entropy.stop1984.com/"
SRC_URI="http://entropy.stop1984.com/files/entropy_rsa-${MY_PV}-${MY_PV_BUILD}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="mysql"

DEPEND="mysql? ( dev-db/mysql )"
RDEPEND="app-admin/sudo"

S=${WORKDIR}/${PN}-${MY_PV}

src_compile() {
	local myconf=""
	if use mysql
	then
		myconf="--with-mysql=/usr"
	else
		myconf="--with-tree"
	fi
	
	econf ${myconf} || die
	emake || die
}

src_install() {
	dobin entropy_rsa monoopt storechg || die
	exeinto /etc/init.d
	newexe ${FILESDIR}/entropy_rsa.rc entropy_rsa
	insinto /etc/conf.d
	newins ${FILESDIR}/entropy_rsa.conf.d entropy_rsa

	pkg_preinst
	diropts -o entropy -g entropy
	insopts -o entropy -g entropy -m0644
	dodir /var/entropy/{de,chat,node,store,tmp}
	insinto /var/entropy/de
	doins de/*
	insinto /var/entropy/node
	doins node/*
	insinto /var/entropy/chat
	doins chat/*
	
	# dont't overwrite the old one
	local CONFIG=entropy_rsa.conf
	if [ -f /var/entropy/${CONFIG} ]
	then
		CONFIG=entropy_rsa.conf-gentoo
	fi
	
	sed -e "3,$ s:#::g" seed.txt-dist > seed.txt
	sed \
		-e "s:seednodes=seed.txt:seednodes=/var/entropy/seed.txt:g" \
		-e "s:logfile=entropy_rsa.log:logfile=/var/entropy/entropy_rsa.log:g" \
		-e "s:storepath=store:storepath=/var/entropy/store:g" \
		-e "s:temppath=tmp:temppath=/var/entropy/tmp:g" \
		-e "s:runpath=./:runpath=/var/entropy/:g" \
		entropy_rsa.conf-dist > ${CONFIG}
	
	if use mysql
	then
		cat>>${CONFIG}<< "EOF"
# All the options below this point are for the MySQL data store.  If you
# are not using MySQL, you can stop now.
# The login name you use to access MySQL.  This user needs to have
# permission to create, drop, and optimize tables, and to insert, select,
# update, and delete data in MySQL.
mysql_user=myname

# The password for mysql_user
mysql_pass=mypass

# The name of the database Entropy will store its tables in.  You have to
# create this database before running Entropy.
mysql_db=entropy_rsa

# If your database server is not running on the same computer as your
# Entropy node, enter the database server's hostname here.
mysql_host=localhost

# The port number MySQL is using.  If you are using the default MySQL
# port, you can just leave this set to zero.
mysql_port=0

# Set this flag to non-zero (or true, or yes) to enable optimization of
# your MySQL tables during node start-up. Optimizing will take some time.
mysql_optimize=false

# Set the maximum size for a single mysql table, i.e. the storeXX tables
# If you change this, be sure to have stordepth= set to the number of
# tables you had before (check with mysql). The default table size is 1GB.
mysql_tablesize=1GB

EOF
	fi
	
	insinto /var/entropy
	doins ${CONFIG} seed.txt

	dodoc README TODO entropy_rsa.conf-dist seed.txt-dist
	dohtml ENTROPY.html
	use mysql && dodoc README.MySQL
}

pkg_preinst() {
	enewgroup entropy
	enewuser entropy -1 /bin/false /var/entropy entropy
}