dev-lang/gdc/gdc-0.13.ebuild

gdc-0.13.ebuild (text/plain), 2.60 KB, created by Sigbjørn Lund Olsen on 2005-06-15 13:26:29 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License, v2 or later
# $Header: $

inherit eutils flag-o-matic toolchain-funcs

IUSE="nls"

#need to check what gcc version we are running
GCC_PV=`gcc-version`
GCC_PVS=`gcc-major-version`.`gcc-minor-version`.`gcc-micro-version`
GCC_PVF=`gcc-fullversion`
GCC_LIBS="`gcc-config --get-lib-path`"

# GCC_LIBS must be saved before we inherit toolchain
# toolchain makes gcc-config not work
# toolchain is used to patch the version
inherit toolchain

DESCRIPTION="D GCC Frontend"
SRC_URI="http://home.earthlink.net/~dvdfrdmn/d/gdc-${PV}.tar.bz2
		ftp://gcc.gnu.org/pub/gcc/releases/gcc-${GCC_PVS}/gcc-${GCC_PVS}.tar.bz2"

HOMEPAGE="http://home.earthlink.net/~dvdfrdmn/d/"

SLOT="0"
KEYWORDS="~x86 ~PPC"
LICENSE="GPL-2"
S="${WORKDIR}/gcc-${GCC_PVS}"

DEPEND="virtual/libc
		>=sys-devel/gcc-3.3.2"

RDEPEND="virtual/libc
		>=sys-devel/gcc-3.3.2
		!dev-lang/dmd"

src_unpack() {
	unpack "gcc-${GCC_PVS}.tar.bz2"
	
	cd "${S}/gcc"
	gcc_version_patch "${GCC_PVF}"

	unpack "gdc-${PV}.tar.bz2"

	cd "${S}"
	ln -s gcc/d/phobos libphobos

	if [ "${GCC_PV}" != "3.3" -a "${GCC_PV}" != "3.4" ]
	then
	    die "GCC ${GCC_PV} not supported by GDC"
	fi
	
	cd "${S}"
	epatch "${S}/gcc/d/patch-toplev-${GCC_PV}.x"
	cd "${S}/gcc"
	epatch "${S}/gcc/d/patch-gcc-${GCC_PV}.x"
}

src_compile() {
	einfo "Configuring GCC for GDC inclusion..."

	strip-flags

	# In general gcc does not like optimization, and add -O2 where
	# it is safe.  This is especially true for gcc 3.3 + 3.4
	replace-flags -O? -O2

	# -mcpu is deprecated on these archs, and possibly others
	if use amd64 || use x86 ; then
		setting="`get-flag mcpu`"
		[ ! -z "${setting}" ] && \
			replace-flags -mcpu="${setting}" -mtune="${setting}" && \
			ewarn "-mcpu is deprecated on your arch\a\a\a" && \
			epause 5
	fi
	
	strip-unsupported-flags

	mkdir -p ${WORKDIR}/gdc-build
	cd ${WORKDIR}/gdc-build
	${S}/configure --prefix=/usr --enable-shared --enable-threads=posix --enable-languages=c,d,c++ 

	einfo "Building GDC and Phobos..."
	gmake
}

src_install() {
	cd ${WORKDIR}

	dobin gdc-build/gcc/gdc
	doman gcc-${GCC_PVS}/gcc/d/gdc.1

	# rename to dmd but move to ${WORKDIR} since there already is a directory named "dmd" in old location
	mv gcc-${GCC_PVS}/gcc/d/dmd-script ${WORKDIR}/dmd
	mv gcc-${GCC_PVS}/gcc/d/dmd-script.1 ${WORKDIR}/dmd.1
	dobin ${WORKDIR}/dmd
	doman ${WORKDIR}/dmd.1
	mv ${WORKDIR}/dmd gcc-${GCC_PVS}/gcc/d/dmd-script
	mv ${WORKDIR}/dmd.1 gcc-${GCC_PVS}/gcc/d/dmd-script.1

	dodir "${GCC_LIBS}"
	cp gdc-build/gcc/cc1d ${D}"${GCC_LIBS}"

	cd ${WORKDIR}/gdc-build/*/libphobos
	make install DESTDIR=${D}
}