ultimatestunts-0.5.5.ebuild

ultimatestunts-0.5.5.ebuild (text/plain), 1.24 KB, created by Chris Gianelloni (RETIRED) on 2005-06-14 14:36:52 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

# This works as long as the filename contains the version number without
# dots and a trailing "1".
MY_P="${PN}-srcdata-${PV//.}1"

DESCRIPTION="UltimateStunts will be a remake of the famous DOS-game \"stunts\""
HOMEPAGE="http://www.ultimatestunts.nl"
SRC_URI="mirror://sourceforge/ultimatestunts/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

DEPEND="virtual/opengl
	>=media-libs/openal-20040817
	>=media-libs/libsdl-1.1
	>=media-libs/fmod-3.73"

S=${WORKDIR}/${MY_P}

src_unpack() {
	unpack ${A}

	cd "${S}"

	# corrects some path to conform with fmod ebuild
	sed -i \
		-e 's:fmod/fmod.h:fmod.h:' \
		-e 's:/games/ultimatestunts:/ultimatestunts:' \
		-e "s:./data/:${GAMES_DATADIR}/${PN}/data/:" \
		configure || die "sed failed"
	cd ultimatestunts
	sed -i \
		-e 's:fmod/::' \
		 music.cpp \
		 music.h \
		 sndsample.cpp \
		 sndsample.h \
		 soundobj.cpp \
		 soundobj.h \
		 sound.cpp \
		 sound.h \
		 || die "sed failed"
}

src_install() { 
	egamesinstall || die

	games_make_wrapper ultimatestunts ./ultimatestunts.sh ${dir}
	make_desktop_entry ultimatestunts.sh "Ultimate Stunts"

	prepgamesdirs
}