cinelerra-gg-5.1.20190430.ebuild

cinelerra-gg-5.1.20190430.ebuild (text/plain), 1.74 KB, created by Nikita Zlobin on 2020-02-02 17:04:56 UTC

# Copyright 2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit autotools multilib

DESCRIPTION="The most advanced non-linear video editor and compositor (goodguy branch)"
HOMEPAGE="https://www.cinelerra-gg.org"
SRC_URI="https://cinelerra-gg.org/download/pkgs/src/cin_${PV}-src.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

IUSE="alsa dv dvb ieee1394 ladspa lv2 numa opencv openexr opengl shuttle static usb v4l2 xf86vm xft"

DEPEND="
	virtual/os-headers
	lv2? ( x11-libs/gtk+:2 )
	opengl? ( virtual/opengl virtual/glu )
	xft? ( x11-libs/libXft )
	alsa? ( media-libs/alsa-lib )
	xf86vm? ( x11-libs/libXxf86vm )
	shuttle? ( x11-base/xorg-proto )
	usb? ( virtual/libusb:1 )
	opencv? ( media-libs/opencv[contrib_xfeatures2d,contrib_ximgproc] )
	numa? ( sys-process/numactl )
	"
RDEPEND="${DEPEND}"
BDEPEND=""

S="${WORKDIR}/cinelerra-$(ver_cut 1-2 ${PV})"

src_prepare() {
	default
	./autogen.sh
}

src_configure() {
	econf \
		--with-plugindir=/usr/$(get_libdir)/${PN} \
		--with-buildinfo=cust/"Gentoo - ${PV}" \
		--with-exec-name=cinelerra-gg \
		--enable-static-build=$(usex static) \
		--with-ladspa-build=$(usex ladspa) \
		--with-lv2=$(usex lv2) \
		--with-gl=$(usex opengl) \
		--with-xft=$(usex xft) \
		--without-oss \
		--with-alsa=$(usex alsa) \
		--with-firewire=$(usex ieee1394) \
		--with-dv=$(usex dv) \
		--with-dvb=$(usex dvb) \
		--with-video4linux2=$(usex v4l2) \
		--with-xxf86vm=$(usex xf86vm) \
		--with-shuttle=$(usex shuttle) \
		--with-shuttle_usb=$(usex usb) \
		--with-opencv=$(usex opencv sys no) \
		--with-numa=$(usex numa) \
		--with-openexr=$(usex openexr) \
		--with-dl \
		--with-libzmpeg
#		--with-noelision \
#		--with-booby \
}

src_install() {
	emake install -j1 DESTDIR="${D}"
}