lincity-ng-0.9_rc1.ebuild

lincity-ng-0.9_rc1.ebuild (text/plain), 1.40 KB, created by Anno v. Heimburg on 2005-06-06 01:41:19 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-simulation/lincity/lincity-1.12.1.ebuild,v 1.2 2005/02/17 15:38:17 mr_bones_ Exp $

inherit games eutils

MY_PV=${PV/_rc/rc}
MY_P="${PN}-${MY_PV}"

DESCRIPTION="city/country simulation game for X and opengl"
HOMEPAGE="http://lincity-ng.berlios.de/"
SRC_URI="http://download.berlios.de/lincity-ng/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~ppc"
IUSE=""
		  
RDEPEND="virtual/x11
	virtual/opengl
	>=sys-libs/zlib-1.0.0
	>=dev-libs/libxml2-2.6.11
	>=media-libs/libsdl-1.2.5
	>=media-libs/sdl-mixer-1.2.4
	>=media-libs/sdl-image-1.2.3
	>=media-libs/sdl-ttf-2.0.0
	>=media-libs/sdl-gfx-2.0.13
	>=dev-games/physfs-1.0.0"
  
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	>=dev-util/jam-2.5"

pkg_setup() {
	if ! built_with_use -o media-libs/sdl-mixer vorbis oggvorbis ; then
		eerror "lincity-ng doesn't work properly if"
		eerror "sdl-mixer is built without vorbis support"
		die "Please emerge sdlmixer with USE=vorbis"
	fi
	games_pkg_setup
}

S="${WORKDIR}/${MY_P}"

src_compile() {	
	egamesconf || die "configure failed"
	jam || die "jam failed"
}

src_install() {
	jam -sDESTDIR="${D}" \
		 -sappdocdir="/usr/share/doc/${PF}" \
		 -sapplicationsdir="/usr/share/applications" \
		 -spixmapsdir="/usr/share/pixmaps" \
		 install \
		 || die "jam install failed"
		 
	prepgamesdirs
}