Updated ebuild

mu-conference-0.6.0-r2.ebuild (text/plain), 2.50 KB, created by Slobodan D. Sredojevic on 2005-06-04 08:40:05 UTC

inherit eutils

JCR_VERSION="0.2.4"

DESCRIPTION="Multi-User Chat for jabberd"
HOMEPAGE="http://mu-conference.jabberstudio.org/"
SRC_URI="http://www.jabberstudio.org/files/mu-conference/${P}.tar.gz
		jabber2? http://jabber.terrapin.com/JCR/jcr-${JCR_VERSION}.tar.gz
		"

LICENSE="GPL-2"
KEYWORDS="~x86 ~sparc ~ppc"
SLOT="0"

IUSE="jabber2"

DEPEND="jabber2? ( >=net-im/jabberd-2 )
		!jabber2? ( =net-im/jabberd-1.4* )
		>=dev-libs/glib-2.2.1
		dev-util/pkgconfig"

if use jabber2; then
	S=${WORKDIR}/jcr-${JCR_VERSION}
else
	S=${WORKDIR}/${P}
fi

src_unpack() {
	if use jabber2; then
		unpack jcr-${JCR_VERSION}.tar.gz
		cd jcr-${JCR_VERSION}
		unpack ${P}.tar.gz
	else
		unpack ${A}
		cd ${S}/src
		epatch ${FILESDIR}/mu-conference-makefile.patch
	fi
}

src_compile() {
	if use jabber2; then
		emake || die
		cp src/main.c src/jcomp.mk ${P}/src || die
		cd ${P}/src
		emake -f jcomp.mk || die
	else
		emake || die
	fi
	
}

src_install() {

	if use jabber2; then
		dodir /etc/jabberd /usr/bin
		
		exeinto /usr/bin
		doexe ${P}/src/mu-conference
		
		dodir  /var/jabberd/log/conference
		keepdir /var/jabberd/log/conference/

		fowners jabber:jabber /var/jabberd/log/conference
		fperms g-x /var/jabberd/log/conference
		fperms g+rw /var/jabberd/log/conference
		
		dodir  /var/jabberd/spool/conference
		keepdir /var/jabberd/spool/conference/
		fowners jabber:jabber /var/jabberd/spool
		fowners jabber:jabber /var/jabberd/spool/conference

		insinto /etc/jabberd
		doins  ${FILESDIR}/muc-jcr.xml || die		
		fowners jabber:jabber /etc/jabberd/muc-jcr.xml
		fperms 640 /etc/jabberd/muc-jcr.xml
		
		dodoc README.jcr
		
		insinto /etc/conf.d 
		newins ${FILESDIR}/mu-conference-conf.d-jabber2 muc-transport || die
	else
		dodir /etc/jabber /usr/lib/jabberd
		
		insinto /usr/lib/jabberd
		doins src/mu-conference.so || die
		
		dodir  /var/log/jabber/conference
		keepdir /var/log/jabber/conference/

		fowners jabber:jabber /var/log/jabber/conference
		fperms g-x /var/log/jabber/conference
		fperms g+rw /var/log/jabber/conference
		
		insinto /etc/jabber
		doins  ${FILESDIR}/muctrans.xml || die		
		
		insinto /etc/conf.d 
		newins ${FILESDIR}/mu-conference-conf.d-jabber14 muc-transport || die		
	fi

	exeinto /etc/init.d
	newexe ${FILESDIR}/muc-transport.init-r3 muc-transport
								   
	
	dodoc README FAQ ${FILESDIR}/README.Gentoo
}

pkg_postinst() {
	einfo
	einfo "Please read /usr/share/doc/${P}/README.Gentoo.gz"
	einfo "And please notice that now muc-transport comes with a init.d script"
	einfo "dont forget to add it to your runlevel."
	einfo
}