# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit java-pkg

MY_PN=JacORB
MY_PV=2_2_1
MY_P="${MY_PN}_${MY_PV}"
DESCRIPTION="The free Java implementation of the OMG's CORBA standard."
HOMEPAGE="http://www.jacorb.org/"
SRC_URI="http://www.jacorb.org/releases/${PV}/${MY_P}-full.tar.gz"


LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="doc"

# TODO: test other vm's
DEPEND=">=virtual/jdk-1.4
	dev-java/ant"
RDEPEND=">=virtual/jre-1.4
	dev-java/ant-tasks
	=dev-java/avalon-logkit-2*
	dev-java/concurrent-util
	=dev-java/avalon-logkit-2.0*
	dev-java/wrapper"
S="${WORKDIR}/${MY_P}"

ANT_ANTLR="ant-tasks ant-antlr.jar"
AVALON_FRAMEWORK="avalon-framework-4.1 avalon-framework.jar"
CONCURRENT="concurrent-util concurrent.jar"
LOGKIT="avalon-logkit-2.0 avalon-logkit.jar logkit.jar"
WRAPPER="wrapper wrapper.jar wrapper-3.1.0.jar"

src_unpack() {
	unpack ${A}

	einfo "Fixing jars in lib/"
	cd ${S}/lib
	java-pkg_jar-from ${ANT_ANTLR} &&
	java-pkg_jar-from ${AVALON_FRAMEWORK} &&
	java-pkg_jar-from ${CONCURRENT} &&
	java-pkg_jar-from ${LOGKIT} &&
	java-pkg_jar-from ${WRAPPER} || die "Failed to use JARs from packages"
}

src_compile() {
	# TODO patch build.xml's clean to delete this package's jars
	rm lib/{idl,jacorb}.jar || die "Failed to clean build directory"

	local antflags
	local targets="all core_jacorb_jar jacorb_services_jar omg_services_jar \
	http_tunneling_jar security_jar"
	use doc && targets="${targets} doc"
	ant ${antflags} ${targets} || die "Failed to compile"

	einfo "Cleaning out unnessary files from bin/"
	cd ${S}/bin
	rm -f *.bat *template* *.exe

}

src_install() {
	# TODO: install bins?

	dodoc doc/REL_NOTES doc/Coding.txt
	if use doc; then
		java-pkg_dohtml -r doc/*.html doc/api/
	fi

	cd ${S}/lib
	java-pkg_dojar core_jacorb.jar http_tunneling.jar idl.jar jacorb.jar \
		jacorb_services.jar omg_services.jar security.jar

}