avogadrolibs-1.92.1.ebuild

avogadrolibs-1.92.1.ebuild (text/plain), 2.18 KB, created by Pacho Ramos on 2019-12-31 19:38:25 UTC

# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=6
inherit cmake-utils

DESCRIPTION="Advanced molecule editor and visualizer 2 - libraries"
HOMEPAGE="https://www.openchemistry.org/"

# From Fedora:
# External source code for avogadrolibs >= 1.91.0
# See https://github.com/OpenChemistry/avogadrolibs/issues/362
GENERATORSCOMMIT="f5a3f98dddda8a776759939a149b4ebb51547507"

SRC_URI="
	https://github.com/OpenChemistry/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz
	https://github.com/OpenChemistry/avogenerators/archive/${GENERATORSCOMMIT}/avogenerators-${GENERATORSCOMMIT}.tar.gz#/avogenerators-${GENERATORSCOMMIT}.tar.gz
	vtk? ( https://github.com/psavery/genXrdPattern/releases/download/1.0-static/linux64-genXrdPattern )
"

SLOT="0"
LICENSE="BSD GPL-2+"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="archive doc hdf5 qt5 static-plugins test vtk"
RESTRICT="!test? ( test )"

REQUIRED_USE="vtk? ( qt5 )"

# TODO: Not yet packaged:
# sci-libs/libmsym (https://github.com/mcodev31/libmsym)
# sci-libs/spglib (https://atztogo.github.io/spglib/)
RDEPEND="
	dev-libs/jsoncpp:=
	>=sci-chemistry/molequeue-0.7
	sci-libs/spglib
	archive? ( app-arch/libarchive )
	hdf5? ( sci-libs/hdf5:= )
	qt5? (
		dev-qt/qtconcurrent:5
		dev-qt/qtcore:5
		dev-qt/qtgui:5
		dev-qt/qtnetwork:5
		dev-qt/qtwidgets:5
		media-libs/glew:0=
		virtual/opengl
	)
	vtk? ( sci-libs/vtk[qt5,views] )
"
DEPEND="${RDEPEND}
	dev-cpp/eigen:3
	qt5? ( dev-qt/linguist-tools:5 )
	test? ( dev-cpp/gtest )"

src_unpack() {
	default
	if use vtk; then
		cp "${DISTDIR}"/linux64-genXrdPattern "${WORKDIR}/genXrdPattern" || die
	fi
}

src_configure() {
	local mycmakeargs=(
		-DUSE_PROTOCALL=OFF
		-DBUILD_GPL_PLUGINS=ON
		-DUSE_MOLEQUEUE=ON
		-DUSE_MMTF=OFF
		-DUSE_LIBMSYM=OFF
		-DUSE_LIBSPG=OFF
		-DUSE_PYTHON=OFF
		-DUSE_LIBARCHIVE=$(usex archive)
		-DBUILD_DOCUMENTATION=$(usex doc)
		-DUSE_HDF5=$(usex hdf5)
		-DENABLE_TRANSLATIONS=$(usex qt5)
		-DUSE_OPENGL=$(usex qt5)
		-DUSE_QT=$(usex qt5)
		-DBUILD_STATIC_PLUGINS=$(usex static-plugins)
		-DENABLE_TESTING=$(usex test)
		-DUSE_VTK=$(usex vtk)
	)
	use vtk && mycmakeargs+=(
		-DBUNDLED_GENXRDPATTERN="${WORKDIR}/genXrdPattern"
	)

	cmake-utils_src_configure
}