# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7
PYTHON_COMPAT=( python3_{6,7,8} )

inherit autotools python-r1 xdg-utils toolchain-funcs

MY_PV=${PV/_alpha/-alpha.}
MY_PV=${MY_PV/_beta/-beta.}
MY_P=${PN}-${MY_PV}

DESCRIPTION="Library for making brushstrokes"
HOMEPAGE="https://github.com/mypaint/libmypaint"

if [[ ${PV} == *9999 ]] ; then
	EGIT_REPO_URI="https://github.com/mypaint/libmypaint"
	inherit git-r3
else
	SRC_URI="https://github.com/mypaint/libmypaint/archive/v${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
	S="${WORKDIR}"/${MY_P}
fi

LICENSE="ISC"
SLOT="0/$(ver_cut 1-2)"  # https://github.com/mypaint/libmypaint/wiki/Versioning
IUSE="gegl introspection nls openmp"

CDEPEND="
	dev-libs/glib:2
	dev-libs/json-c:=
	gegl? (
		media-libs/babl
		>=media-libs/gegl-0.4.14:0.4[introspection?]
	)
	introspection? ( >=dev-libs/gobject-introspection-1.32 )
	openmp? ( sys-devel/gcc:*[openmp] )
	nls? ( sys-devel/gettext )
	"
DEPEND="${CDEPEND}
	${PYTHON_DEPS}
	nls? ( dev-util/intltool )
	"
RDEPEND="${CDEPEND}
	!<media-gfx/mypaint-1.2.1
	"

src_prepare() {
	xdg_environment_reset
	default
	eautoreconf
	./autogen.sh || die
}

src_configure() {
	econf \
			--disable-debug \
			--disable-docs \
			$(use_enable gegl) \
			--disable-gperftools \
			$(use_enable nls i18n) \
			$(use_enable introspection) \
			$(use_enable openmp) \
			--disable-profiling
}

src_install() {
	default
	find "${D}" -name '*.la' -type f -delete || die
}