@@ -, +, @@ 
---
 x11-misc/xsecurelock/Manifest                 |  1 +
 x11-misc/xsecurelock/metadata.xml             | 16 +++++
 x11-misc/xsecurelock/xsecurelock-1.5.1.ebuild | 68 +++++++++++++++++++
 3 files changed, 85 insertions(+)
 create mode 100644 x11-misc/xsecurelock/Manifest
 create mode 100644 x11-misc/xsecurelock/metadata.xml
 create mode 100644 x11-misc/xsecurelock/xsecurelock-1.5.1.ebuild
--- a/x11-misc/xsecurelock/Manifest	
+++ a/x11-misc/xsecurelock/Manifest	
@@ -0,0 +1, @@ 
+DIST xsecurelock-1.5.1.tar.gz 213362 BLAKE2B a6e753b10e025008e053f5f7170dba96e1c946de6962ac4a7287cf155a1437f253f883cd6183d061fcb6213de464d19b27d2616f42cf7dfad4eda408d8e7cf25 SHA512 57ac1f6ad58dc4aa9288127fda474f708a653bdc9de31983e074839cd2e52c1f4af263832d2d8559db9233a60b281e41b8ac551e92db0343ad1d919778b73d67
--- a/x11-misc/xsecurelock/metadata.xml	
+++ a/x11-misc/xsecurelock/metadata.xml	
@@ -0,0 +1,16 @@ 
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>ngg@ngg.hu</email>
+    <name>Gergely Nagy</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>proxy-maint@gentoo.org</email>
+    <name>Proxy Maintainers</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="github">google/xsecurelock</remote-id>
+    <bugs-to>https://github.com/google/xsecurelock/issues</bugs-to>
+  </upstream>
+</pkgmetadata>
--- a/x11-misc/xsecurelock/xsecurelock-1.5.1.ebuild	
+++ a/x11-misc/xsecurelock/xsecurelock-1.5.1.ebuild	
@@ -0,0 +1,68 @@ 
+# Copyright 2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="X11 screen lock utility with security in mind"
+HOMEPAGE="https://github.com/google/xsecurelock"
+SRC_URI="https://github.com/google/${PN}/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="xscreensaver"
+
+RDEPEND="
+	dev-libs/libbsd
+	media-libs/fontconfig
+	media-libs/freetype
+	sys-apps/util-linux
+	sys-libs/pam
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXft
+	x11-libs/libXmu
+	x11-libs/libXrandr
+	x11-libs/libXScrnSaver
+	x11-libs/libXxf86misc
+	xscreensaver? ( x11-misc/xscreensaver )
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--prefix="${EPREFIX}"/usr
+		--with-default-auth-module=auth_x11
+		--with-default-authproto-module=authproto_pam
+		--without-htpasswd
+		--without-mplayer
+		--without-mpv
+		--without-pamtester
+		--without-pandoc
+		--with-pam-service-name=system-auth
+	)
+	if use xscreensaver; then
+		myeconfargs+=(
+			--with-default-saver-module=saver_xscreensaver
+			--with-xscreensaver="${EPREFIX}"/usr/$(get_libdir)/misc/xscreensaver
+		)
+	else
+		myeconfargs+=(
+			--with-default-saver-module=saver_blank
+			--without-xscreensaver
+		)
+	fi
+	econf "${myeconfargs[@]}"
+}
--