# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit autotools

MY_COMMIT="e73199781397156be57866688a18d522d43c78ef"

DESCRIPTION="Utility for creating and opening lzh archives"
HOMEPAGE="https://github.com/jca02266/lha https://lha.osdn.jp"
SRC_URI="https://github.com/jca02266/lha/archive/${MY_COMMIT}.tar.gz -> ${P}.tar.gz"

LICENSE="lha"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~m68k-mint"

S="${WORKDIR}/${PN}-${MY_COMMIT}"

PATCHES=(
	"${FILESDIR}"/${P/_p*}-file-list-from-stdin.patch
	"${FILESDIR}"/${P/_p*}-fix-getopt_long-declaration.patch
)

src_prepare() {
	default

	sed -e 's/^AM_CONFIG_HEADER/AC_CONFIG_HEADERS/' \
		-i configure.ac || die #467544

	eautoreconf
}

src_configure() {

	if [[ ${CHOST} == *-interix* ]]; then
		export ac_cv_header_inttypes_h=no
		export ac_cv_func_iconv=no
	fi

	default
}

src_install() {
	default

	dodoc ChangeLog Hacking_of_LHa
}