# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

DESCRIPTION="GNOME frontend for the popular X-Chat IRC client"
HOMEPAGE="http://xchat-gnome.navi.cx/"
SRC_URI="http://flapjack.navi.cx/releases/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="X ipv6 gnome gtk mmx nls perl python ssl tcltk"

RDEPEND=">=dev-libs/glib-2.0.3
	gnome? ( =gnome-base/libgnomeui-2* )
	gtk? ( >=x11-libs/gtk+-2.3.1 )
	ssl? ( >=dev-libs/openssl-0.9.6d )
	perl? ( >=dev-lang/perl-5.6.1 )
	python? ( >=dev-lang/python-2.3 )
	tcltk? ( dev-lang/tcl )
	!net-irc/xchat"

DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.7
	nls? ( sys-devel/gettext )"

src_compile() {

	# xchat's configure script uses sys.path to find library path
	# instead of python-config (#25943)
	unset PYTHONPATH

	econf \
		$(use_enable nls) \
		$(use_enable ipv6) \
		$(use_enable ssl openssl) \
		$(use_enable gtk gtkfe) \
		$(use_enable !X textfe) \
		$(use_enable gnome gnomefe) \
		$(use_enable python) \
		$(use_enable perl) \
		$(use_enable tcltk tcl) \
		$(use_enable mmx) \
		|| die "econf failed"

	emake || die "emake failed"

}

src_install() {

	make DESTDIR=${D} install || die "make install"

	# install plugin development header
	insinto /usr/include/xchat
	doins src/common/xchat-plugin.h || die "doins failed"

	dodoc \
		src/fe-gnome/BUGS \
		src/fe-gnome/ChangeLog \
		src/fe-gnome/TODO \
	|| die "dodoc failed"

}