new r5 ebuild with patch

libnss-mysql-1.5_p20060915-r5.ebuild (text/plain), 1.21 KB, created by Jan Hudoba on 2019-09-03 10:30:15 UTC

# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit autotools

KEYWORDS="amd64 ppc ~sparc x86"

DESCRIPTION="NSS MySQL Library"
HOMEPAGE="http://libnss-mysql.sourceforge.net/"
SRC_URI="http://libnss-mysql.sourceforge.net/snapshot/${PN}-${PV/1.5_p/}.tgz"
LICENSE="GPL-2"
SLOT="0"
IUSE="debug"

DEPEND="dev-db/mysql-connector-c:="
RDEPEND="${DEPEND}"
S="${WORKDIR}/${PN}"

DOCS=( AUTHORS DEBUGGING FAQ INSTALL NEWS README THANKS
	TODO UPGRADING ChangeLog
)
PATCHES=(
	"${FILESDIR}"/${P}-no-automagic-debug.diff
	"${FILESDIR}"/${P}-mariadb-bool.diff
)

src_prepare() {
	default
	eautoconf
}

src_configure() {
	# Usually, authentication libraries don't belong into usr.
	# But here, it's required that the lib is in the same dir
	# as libmysql, because else failures may occur on boot if
	# udev tries to access a user / group that doesn't exist
	# on the system before /usr is mounted.
	econf --libdir="/usr/$(get_libdir)" \
		$(use_enable debug)
}

src_install() {
	default

	find "${D}" -name '*.la' -delete

	newdoc sample/README README.sample

	for subdir in sample/{linux,freebsd,complex,minimal} ; do
		docinto "${subdir}"
		dodoc "${subdir}/"{*.sql,*.cfg}
	done
}