mute-0.4.1.ebuild

mute-0.4.1.ebuild (text/plain), 3.22 KB, created by Mark Byers on 2005-05-13 14:53:08 UTC

inherit eutils

MY_P="MUTE_fileSharing-${PV}_UnixSource"

DESCRIPTION="A simple, anonymous filesharing client"
HOMEPAGE="http://mute-net.sourceforge.net/"
SRC_URI="mirror://sourceforge/mute-net/${MY_P}.tar.gz"
RESTRICT="nomirror"

LICENSE="GPL-2"
SLOT="0"

KEYWORDS="~x86"
IUSE="debug wxwindows"

DEPEND="wxwindows? ( =x11-libs/wxGTK-2.4.2* )"

S="${WORKDIR}/${MY_P}"

src_unpack() {
	unpack ${A} || die "Couldn't unpack${A}"
	cd ${S}/MUTE  
	epatch ${FILESDIR}/MUTE-crypto++-GCC-3.4-compilation.patch
	cd ${S}
	epatch ${FILESDIR}/MUTE-linux-path-style-quick-hack.patch
}


src_compile() {
	# set answers for multiple choice configure script
	# set arch to: linux x86
	sed -i -e 's/\(.\+\)read userEntry/\1userEntry=1/'  MUTE/configure 
	
	if use wxwindows; then
		#check if wx-config points to the unicode install of wxGTK
		# if yes, use gtk2 or gtk1 variant instead
		wx-config --libs | grep "lwx_gtk2u-2.4" &> /dev/null
		if [ $? -eq 0 ]; then
			if [ -x /usr/bin/wxgtk2-2.4-config ]; then
				WXCONFIG="/usr/bin/wxgtk2-2.4-config"
			elif [ -x /usr/bin/wxgtk-2.4-config ]; then
				WXCONFIG="/usr/bin/wxgtk-2.4-config"
			else
				die "cant find proper wx-config"
			fi
		else
			WXCONFIG="/usr/bin/wx-config"
		fi
	fi
		
	# set wxconfig
	sed -i -e "s:^read userEntry:userEntry=\"${WXCONFIG}\":"  MUTE/configure

	# use portage $CXXFLAGS variable 
	sed -i -e  's/^\(COMPILE_FLAGS = \)\(.*\)/\1$(CXXFLAGS) \2/' MUTE/Makefile.common

	WXMAKEFILE=MUTE/otherApps/fileSharing/userInterface/wxWindows/Makefile.all

	if use debug; then
		sed -i -e 's/^DEBUG_FLAG = .*/DEBUG_FLAG = -g/' MUTE/Makefile.common
		sed -i -e 's/g++ -g/g++ $(CXXFLAGS) -g -Wall/' ${WXMAKEFILE}
	else
		sed -i -e 's/^DEBUG_FLAG = .*/DEBUG_FLAG =/' MUTE/Makefile.common
		sed -i -e 's/g++ -g/g++ $(CXXFLAGS) -Wall/' ${WXMAKEFILE}
	fi
	
	# let the script produce our make files
	cd ${S}/MUTE
	chmod u+x ./configure
	./configure &> /dev/null
	cd ${S}
	# build stuff
	emake -C MUTE/crypto libcrypto.a || die 
	emake -C MUTE/layers/messageRouting libmuteMessageRouter.a || die 
	emake -C MUTE/otherApps/fileSharing libmuteFileShare.a || die
	if use wxwindows; then
		emake -C MUTE/otherApps/fileSharing/userInterface/wxWindows || die
	else
		emake -C MUTE/otherApps/fileSharing/userInterface/textBased || die
	fi
}

src_install() {
	# install binary
	exeinto /usr/bin
	if use wxwindows; then
		BINPATH=MUTE/otherApps/fileSharing/userInterface/wxWindows
		BINFILENAME=fileSharingMUTE
	else
		BINPATH=MUTE/otherApps/fileSharing/userInterface/textBased
		BINFILENAME=textFileSharingMUTE
	fi
	doexe ${BINPATH}/${BINFILENAME}
	# rename it to better name
	mv ${D}/usr/bin/{${BINFILENAME},MUTE}
	
	# install language data,remove TranslationHelper(is 0bytes)
	dodir /usr/share/MUTE/
	insinto /usr/share/MUTE/language/
	doins MUTE/otherApps/fileSharing/userInterface/languages/*
	rm ${D}/usr/share/MUTE/language/TranslationHelper.txt
	insinto /usr/share/MUTE
	doins MUTE/otherApps/fileSharing/userInterface/settings/mime.ini
	doins MUTE/otherApps/fileSharing/userInterface/settings/webHostCaches.ini
	
	# install various documents
	dodoc MUTE/otherApps/fileSharing/userInterface/settings/README.txt
	dodoc MUTE/otherApps/fileSharing/doc/fileSharingProtocol.txt
	dodoc minorGems/protocol/p2p/*
	docinto crypto
	dodoc MUTE/crypto/LICENSE.txt
}