# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/dom4j/dom4j-1.5.ebuild,v 1.4 2005/04/09 16:07:17 corsair Exp $

inherit java-pkg

DESCRIPTION="Easy to use, open source library for working with XML, XPath and XSLT on the Java platform using the Java Collections Framework and with full support for DOM, SAX and JAXP."
HOMEPAGE="http://dom4j.sourceforge.net/"
SRC_URI="mirror://sourceforge/dom4j/${P}.tar.gz"
LICENSE="Apache-1.1"
SLOT="1"
KEYWORDS="~x86"
IUSE="doc"
DEPEND=">=virtual/jdk-1.3
	dev-java/ant
	=dev-java/jaxen-1.1*
	=dev-java/xerces-2*
	dev-java/junitperf
	dev-java/iso-relax
	dev-java/jtidy
	dev-java/xalan"
RDEPEND=">=virtual/jdk-1.3
	=dev-java/jaxen-1.1*
	=dev-java/xerces-2*
	dev-java/junitperf
	dev-java/iso-relax
	dev-java/jtidy
	dev-java/xalan"

src_unpack() {
	unpack ${A}

	# Use jar files provided by packages
	cd ${S}/lib
	java-pkg_jar-from jaxen-1.1 jaxen.jar jaxen-1.1-beta-4.jar
	# TODO: replace jaxme-api-0.3.jar
	# TODO: replace jsr173_1.0_api.jar
	# TODO: replace msv-20030807.jar
	# TODO: replace pull-praser-2.jar
	# TODO: replace relaxngDatatype-20030807.jar
	# TODO: replace xsdlib-20030807.jar

	cd ${S}/lib/endorsed
	java-pkg_jar-from xerces-2 xml-apis.jar

	cd ${S}/lib/test
	# TODO: replace jsr173_1.0_ri.jar
	java-pkg_jar-from junitperf junitperf-1.8.jar

	cd ${S}/lib/tools
	# TODO: replace clover-1.3.1.jar
	java-pkg_jar-from iso-relax isolrelax.jar isorelax-20030108.jar
	# TODO: replace jaxme-0.3.jar
	# TODO: replace jaxme-js-0.3.jar
	# TODO: replace jaxme-xs-0.3.jar
	java-pkg_jar-from jtidy Tidy.jar jtidy-4aug200r7-dev.jar
	java-pkg_jar-from xalan xalan.jar xalan-2.5.1.jar
	java-pkg_jar-from xerces-2 xercesImpl.jar
}

src_compile() {
	ant clean package || die "Compilation Failed"
	if use doc; then
		ant javadoc || die "Javadoc Failed"
	fi
}

src_install() {
	java-pkg_dojar build/${PN}.jar
	use doc && dohtml -r build/doc/*
}