# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/dom4j/dom4j-1.4-r1.ebuild,v 1.9 2005/04/22 08:25:49 blubb Exp $

inherit eutils java-pkg

DESCRIPTION="Easy to use, open source library for working with XML, XPath and XSLT on the Java platform using the Java Collections Framework and with full support for DOM, SAX and JAXP."
HOMEPAGE="http://dom4j.sourceforge.net/"
SRC_URI="mirror://sourceforge/dom4j/${P}.tar.gz"
LICENSE="Apache-1.1"
SLOT="1"
KEYWORDS="~x86"
IUSE="doc"
DEPEND=">=virtual/jdk-1.3
	dev-java/jtidy
	dev-java/ant-core
	dev-java/crimson
	dev-java/iso-relax
	=dev-java/jaxen-1.1*
	dev-java/junit
	dev-java/junitperf
	dev-java/saxpath
	dev-java/xalan
	=dev-java/xerces-2*
	>=dev-java/avalon-framework-4.2
	>=dev-java/batik-1.5.1
	dev-java/fop
	dev-java/jimi
	=dev-java/xerces-1*
	dev-java/saxon-bin"
RDEPEND=">=virtual/jdk-1.3"

src_unpack() {
	unpack ${A}
	cd ${S}

	# fix the build.xml so we can use ant directly (instead of through build.sh)
	epatch ${FILESDIR}/${P}-antscript.patch
	# fix exceptions thrown/caught in a random function
	epatch ${FILESDIR}/${P}-exceptions.patch

	# Use JAR files from installed packages
	cd ${S}/lib
	# TODO: replace PullParser11.jar
	# TODO: replace PullParser2.jar
	#        are these from http://sourceforge.net/projects/xni2xmlpull/ ?
	java-pkg_jar-from jtidy Tidy.jar
	java-pkg_jar-from ant-core
	java-pkg_jar-from ant-tasks # TODO: figure out which jars are needed from here
	java-pkg_jar-from crimson-1 crimson.jar
	java-pkg_jar-from iso-relax isorelax.jar
	# TODO: verify version of jaxen used. I think its 1.1 because of the
	# filename
	java-pkg_jar-from jaxen-1.1 jaxen.jar
	java-pkg_jar-from junit junit.jar
	java-pkg_jar-from junitperf junitperf.jar
	# TODO: replace msv.jar
	# TODO: replace relaxngDatatype.jar
	java-pkg_jar-from saxpath saxpath.jar
	java-pkg_jar-from xalan xalan.jar
	java-pkg_jar-from xerces-2 xercesImpl.jar
	java-pkg_jar-from xerces-2 xml-apis.jar
	# TODO: replace xmldb.jar
	# TODO: replace xsdlib.jar

	cd ${S}/lib/fop
	java-pkg_jar-from avalon-framework-4.2 avalon-framework.jar
	java-pkg_jar-from batik-1.5.1 batik.jar
	java-pkg_jar-from fop fop.jar
	java-pkg_jar-from jimi jimi.jar jimi-1.0.jar
	# TODO: replace logkit-1.0b4 (avalon-logkit from avalon-logkit-2.0?)
	# TODO: replace xalanj1compat.jar
	java-pkg_jar-from xerces-1.3 xerces.jar xerces-1.2.3.jar

	cd ${S}/lib/tool
	java-pkg_jar-from saxon-bin saxon8.jar saxon.jar # TODO: verify this is the right jar
	java-pkg_jar-from xerces-1.3 xerces.jar # TODO: verify this is from the right slot
}

src_compile() {
	ant package
	if use doc; then
		ant doc javadoc
	fi
}

src_install() {
	java-pkg_dojar build/${PN}.jar
	use doc && java-pkg_dohtml -r build/doc/*
}