new hal ebuild that adds haldaemon to the disk and cdrom groups

hal-0.5.1.ebuild (text/plain), 3.99 KB, created by Nathaniel McCallum (RETIRED) on 2005-05-08 10:04:38 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/hal/hal-0.4.7-r2.ebuild,v 1.2 2005/04/24 10:27:20 dsd Exp $

inherit eutils python linux-info versionator flag-o-matic

DESCRIPTION="Hardware Abstraction Layer"
HOMEPAGE="http://www.freedesktop.org/Software/hal"
SRC_URI="http://freedesktop.org/~david/dist/${P}.tar.gz"

LICENSE="|| ( GPL-2 AFL-2.0 )"
SLOT="0"
KEYWORDS="~x86"
IUSE="debug pcmcia doc"

RDEPEND=">=dev-libs/glib-2.4
	>=sys-apps/dbus-0.33
	dev-libs/expat
	>=sys-fs/udev-050
	sys-apps/hotplug
	sys-libs/libcap
	dev-libs/popt
	>=sys-apps/util-linux-2.12i
	|| ( >=sys-kernel/linux-headers-2.6 sys-kernel/linux26-headers )"

DEPEND="${RDEPEND}
	dev-util/pkgconfig
	>=dev-util/intltool-0.29
	doc? ( app-doc/doxygen )"
# dep on a specific util-linux version for 
# managed mount patches #70873

# We need to run at least a 2.6.10 kernel, this is a
# way to ensure that to some extent
pkg_setup() {

	linux-info_pkg_setup
	kernel_is ge 2 6 10 \
		|| die "You need a 2.6.10 or newer kernel to build this package"

}

src_compile() {

	# FIXME : docs
	econf \
		`use_enable debug verbose-mode` \
		`use_enable pcmcia pcmcia-support` \
		--enable-sysfs-carrier \
		--enable-fstab-sync \
		--enable-hotplug-map \
		--disable-docbook-docs \
		`use_enable doc doxygen-docs` \
		--with-pid-file=/var/run/hald/hald.pid \
		|| die

	emake || die

}

src_install() {

	make DESTDIR=${D} install || die

	# We install this in a seperate package to avoid gnome-python dep
	rm ${D}/usr/bin/hal-device-manager

	# initscript
	exeinto /etc/init.d/
	doexe ${FILESDIR}/hald

	# place our pid file
	keepdir /var/run/hald

	# keep the policy setup intact
	keepdir /usr/share/hal/fdi/{95userpolicy,50user,40oem,30osvendor,10generic}

	dodoc AUTHORS COPYING ChangeLog INSTALL NEWS README
}

# Gets the groups of a user, minus the groups in the filter
# char *get_groups(<username>, <comma delimited group filter>)
get_groups() {
        user="$1"
        filter=`echo $2 | sed "s/,/ /g"`
        outgroups=""
        for grp in `groups $user`; do
                for flt in $filter; do
                        [ "$grp" == "$flt" ] && grp=""
                done
                if [ -n "$grp" ]; then
                        if [ -z "$outgroups" ]; then
                                outgroups="$grp"
                        else
                                outgroups="${outgroups},${grp}"
			fi
                fi
        done
        echo "$outgroups"
}


pkg_preinst() {

	enewgroup haldaemon || die "Problem adding haldaemon group"
	# HAL drops priviledges by default now ...
	# ... so we must make sure it can read disk/cdrom info (ie. be in the disk/cdrom groups)
	enewuser haldaemon -1 /bin/false /dev/null haldaemon,cdrom,disk || die "Problem adding haldaemon user"

	# If the user haldaemon is not in haldaemon,disk,cdrom (if the user already exists)
	# add the user to those groups, but do so without killing any user modifications
	if [ "`get_groups haldaemon`" != "disk,cdrom,haldaemon" ]; then
		einfo "Adding user 'haldaemon' to the disk, cdrom and haldaemon groups..."
		groups=`get_groups haldaemon disk,cdrom,haldaemon`
		if [ -z "$groups" ]; then
			groups="disk,cdrom,haldaemon"
		else
			groups="${groups},disk,cdrom,haldaemon"
		fi
		usermod -G "$groups" haldaemon
	fi

}

pkg_postinst() {

	# make sure the permissions on the pid dir are alright & after preinst
	chown haldaemon:haldaemon /var/run/hald

	ewarn "Enabled in this ebuild by default is the usage of fstab-sync"
	ewarn "that will create mount rules for non-existing devices in"
	ewarn "fstab if needed, mount points will be created in /media."
	ewarn "This functionality alters /etc/fstab runtime on the filesystem"
	ewarn "and should be considered a security risk."
	echo
	einfo "The HAL daemon needs to be running for certain applications to"
	einfo "work. Suggested is to add the init script to your start-up"
	einfo "scripts, this should be done like this :"
	einfo "\`rc-update add hald default\`"

}