media-sound/loudness-scanner-9999.ebuild

loudness-scanner-9999.ebuild (text/plain), 1.87 KB, created by Stefan Briesenick on 2019-07-01 13:20:19 UTC

# Copyright 2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit git-r3 cmake-utils

DESCRIPTION="A tool that scans your music files and tags them with loudness information"
HOMEPAGE="https://github.com/jiixyj/loudness-scanner/"
EGIT_REPO_URI="git://github.com/jiixyj/loudness-scanner.git"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64"
IUSE="sndfile ffmpeg mpg123 musepack gtk qt5"
REQUIRED_USE="|| ( sndfile ffmpeg mpg123 musepack )"

DEPEND="
	media-libs/libebur128
	media-libs/taglib
	dev-libs/glib
	ffmpeg?   ( media-video/ffmpeg         )
	mpg123?   ( media-sound/mpg123         )
	sndfile?  ( media-libs/libsndfile      )
	musepack? ( media-sound/musepack-tools )
	gtk? (
		x11-libs/cairo
		x11-libs/gtk+:2
		gnome-base/librsvg:2
	)
	qt5? (
		dev-qt/qtsvg:5
		dev-qt/qtgui:5
		dev-qt/qtcore:5
		dev-qt/qtwidgets:5
	)
"
RDEPEND="${DEPEND}"
BDEPEND=""

src_prepare() {
	cmake-utils_src_prepare
	sed -i 's|".",|"/usr/'$(get_libdir)'/r128",|g' "${S}"/scanner/inputaudio/input.c
}

src_configure() {
	local -a mycmakeargs=(
		-DCMAKE_SKIP_RPATH=True
		-DBUILD_SHARED_LIBS:BOOL=OFF  # we need static internal libs
		-DDISABLE_GSTREAMER:BOOL=ON   # needs gstreamer-0.10
		-DDISABLE_QT4:BOOL=ON         # no qt4 anymore
	)

	use mpg123   || mycmakeargs+=( -DDISABLE_MPG123:BOOL=ON  )
	use musepack || mycmakeargs+=( -DDISABLE_MPCDEC:BOOL=ON  )
	use sndfile  || mycmakeargs+=( -DDISABLE_SNDFILE:BOOL=ON )
	use ffmpeg   || mycmakeargs+=( -DDISABLE_FFMPEG:BOOL=ON  )

	use gtk      || mycmakeargs+=( -DDISABLE_GTK2:BOOL=ON -DDISABLE_RSVG2:BOOL=ON )
	use qt5      || mycmakeargs+=( -DDISABLE_QT5:BOOL=ON  )

	cmake-utils_src_configure
}

src_install() {
	dobin "${BUILD_DIR}"/loudness
	use gtk && dobin "${BUILD_DIR}"/loudness-drop-gtk
	use qt5 && dobin "${BUILD_DIR}"/loudness-drop-qt5
	exeinto /usr/$(get_libdir)/r128
	doexe "${BUILD_DIR}"/libinput_*.so
	einstalldocs
}