[patch] Patch adding libgdata-0.17.9-r2.ebuild and Makefile patch

libgdata-0.17.9-r2.patch (text/plain), 3.63 KB, created by Denis Dupeyron (RETIRED) on 2019-05-21 19:31:48 UTC

From 9fa5a8d8c0dd99b959765d3a79ed479d0240ab9f Mon Sep 17 00:00:00 2001
From: Denis Dupeyron <[e-mail]>
Date: Tue, 21 May 2019 13:21:30 -0600
Subject: [PATCH] dev-libs/libgdata: fix make breakage, bug #686082

---
 .../libgdata-0.17.9-fix-make-breakage.patch   | 29 ++++++++
 dev-libs/libgdata/libgdata-0.17.9-r2.ebuild   | 70 +++++++++++++++++++
 2 files changed, 99 insertions(+)
 create mode 100644 dev-libs/libgdata/files/libgdata-0.17.9-fix-make-breakage.patch
 create mode 100644 dev-libs/libgdata/libgdata-0.17.9-r2.ebuild

diff --git a/dev-libs/libgdata/files/libgdata-0.17.9-fix-make-breakage.patch b/dev-libs/libgdata/files/libgdata-0.17.9-fix-make-breakage.patch
new file mode 100644
index 000000000..102bb5a57
--- /dev/null
+++ b/dev-libs/libgdata/files/libgdata-0.17.9-fix-make-breakage.patch
@@ -0,0 +1,29 @@
+From 4c11ef4b824c352ab0f6b132575b017741c2b29b Mon Sep 17 00:00:00 2001
+From: Denis Dupeyron <[e-mail]>
+Date: Tue, 21 May 2019 13:11:36 -0600
+Subject: [PATCH] Fix make breakage, bug #686082
+
+---
+ Makefile.am | 6 +++---
+ 1 file changed, 3 insertions(+), 3 deletions(-)
+
+diff --git a/Makefile.am b/Makefile.am
+index 044193c..3995689 100644
+--- a/Makefile.am
++++ b/Makefile.am
+@@ -633,9 +633,9 @@ endif
+ endif
+ 
+ # Code coverage
+-@CODE_COVERAGE_RULES@
+-CODE_COVERAGE_DIRECTORY = $(top_builddir)/gdata
+-CODE_COVERAGE_LCOV_OPTIONS = --base-directory $(abs_top_srcdir)
++#@CODE_COVERAGE_RULES@
++#CODE_COVERAGE_DIRECTORY = $(top_builddir)/gdata
++#CODE_COVERAGE_LCOV_OPTIONS = --base-directory $(abs_top_srcdir)
+ 
+ # Demo programs
+ noinst_PROGRAMS = \
+-- 
+2.21.0
+
diff --git a/dev-libs/libgdata/libgdata-0.17.9-r2.ebuild b/dev-libs/libgdata/libgdata-0.17.9-r2.ebuild
new file mode 100644
index 000000000..daf388513
--- /dev/null
+++ b/dev-libs/libgdata/libgdata-0.17.9-r2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+GNOME2_EAUTORECONF="yes"
+
+inherit gnome2 vala
+
+DESCRIPTION="GLib-based library for accessing online service APIs using the GData protocol"
+HOMEPAGE="https://wiki.gnome.org/Projects/libgdata"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/22" # subslot = libgdata soname version
+
+IUSE="+crypt gnome-online-accounts +introspection static-libs test vala"
+REQUIRED_USE="
+	gnome-online-accounts? ( crypt )
+	vala? ( introspection )
+"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.44.0:2
+	>=dev-libs/json-glib-0.15[introspection?]
+	>=dev-libs/libxml2-2:2
+	>=net-libs/liboauth-0.9.4
+	>=net-libs/libsoup-2.55.90:2.4[introspection?]
+	>=x11-libs/gdk-pixbuf-2.14:2
+	crypt? ( app-crypt/gcr:= )
+	gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.8:=[introspection?,vala?] )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.7:= )
+"
+DEPEND="${RDEPEND}
+	dev-util/glib-utils
+	>=dev-util/gtk-doc-am-1.25
+	>=dev-util/intltool-0.40
+	sys-devel/autoconf-archive
+	virtual/pkgconfig
+	test? ( >=net-libs/uhttpmock-0.5 )
+	vala? ( $(vala_depend) )
+"
+# eautoreconf needs autoconf-archive
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.17.8-disable-demos.patch
+	"${FILESDIR}"/${PN}-0.17.9-fix-make-breakage.patch
+)
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-build-demos \
+		$(use_enable crypt gnome) \
+		$(use_enable gnome-online-accounts goa) \
+		$(use_enable introspection) \
+		$(use_enable vala) \
+		$(use_enable static-libs static) \
+		$(use_enable test always-build-tests)
+}
+
+src_test() {
+	unset ORBIT_SOCKETDIR
+	dbus-run-session emake check
+}
-- 
2.21.0