mako-9999.ebuild

mako-9999.ebuild (text/plain), 991 bytes, created by Trevor Slocum on 2019-04-23 11:34:53 UTC

# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit meson

DESCRIPTION="A lightweight Wayland notification daemon"
HOMEPAGE="https://github.com/emersion/mako"

if [[ ${PV} == 9999 ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://github.com/emersion/mako.git"
else
	SRC_URI="https://github.com/emersion/mako/archive/v${PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~amd64 ~x86"
fi

LICENSE="MIT"
SLOT="0"
IUSE="apparmor -icons +man zsh-completion"

DEPEND="
	dev-libs/wayland
	x11-libs/cairo
	x11-libs/pango
	icons? ( x11-libs/gdk-pixbuf:2 )
	apparmor? ( sys-libs/libapparmor )
"
RDEPEND="
	${DEPEND}
"
BDEPEND="
	>=dev-libs/wayland-protocols-1.14
	virtual/pkgconfig
	man? ( app-text/scdoc )
"

src_configure() {
	local emesonargs=(
		-Dicons=$(usex icons enabled disabled)
		-Dman-pages=$(usex man enabled disabled)
		$(meson_use apparmor)
		$(meson_use zsh-completion zsh-completions)
		-Dwerror=false
	)

	meson_src_configure
}