nose2-0.9.0.ebuild

nose2-0.9.0.ebuild (text/plain), 900 bytes, created by Chris Mayo on 2019-03-26 19:39:29 UTC

# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

PYTHON_COMPAT=( python2_7 python3_{5,6,7} )

inherit distutils-r1

DESCRIPTION="nose2 is the next generation of nicer testing for Python"
HOMEPAGE="https://github.com/nose-devs/nose2"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc"

CDEPEND="
	dev-python/setuptools[${PYTHON_USEDEP}]
	dev-python/six[${PYTHON_USEDEP}]
"
DEPEND="
	${CDEPEND}
	doc? ( >=dev-python/sphinx-1.6.5[${PYTHON_USEDEP}] )
"
RDEPEND="
	${CDEPEND}
	>=dev-python/coverage-4.4.1[${PYTHON_USEDEP}]
"

python_compile_all() {
	use doc && emake -C docs html
}

python_test() {
	"${PYTHON}" -m nose2.__main__ || die "tests failed under ${EPYTHON}"
}

python_install_all() {
	use doc && local HTML_DOCS=( docs/_build/html/. )

	distutils-r1_python_install_all
}