Fixed ebuild

metacity-2.10.1.ebuild (text/plain), 1.57 KB, created by Alexey Maximov on 2005-04-18 20:21:44 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/metacity/metacity-2.10.1.ebuild,v 1.1 2005/04/17 14:05:26 joem Exp $

inherit gnome2 eutils

DESCRIPTION="Gnome default windowmanager"
HOMEPAGE="http://www.gnome.org/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~ppc ~alpha ~sparc ~hppa ~amd64 ~ia64 ~mips ~ppc64 ~arm"
IUSE="xinerama"

# not parallel-safe; see bug #14405
MAKEOPTS="${MAKEOPTS} -j1"

RDEPEND="virtual/x11
	>=x11-libs/pango-1.2
	>=x11-libs/gtk+-2.2.0-r1
	>=gnome-base/gconf-2
	>=x11-libs/startup-notification-0.7
	!x11-misc/expocity"

DEPEND="${RDEPEND}
	sys-devel/gettext
	>=dev-util/pkgconfig-0.12.0
	>=dev-util/intltool-0.29"

# Compositor is too unreliable
G2CONF="${G2CONF} $(use_enable xinerama) --disable-compositor"
USE_DESTDIR="1"
DOCS="AUTHORS ChangeLog HACKING NEWS README *txt"

src_unpack() {

	unpack ${A}
	cd ${S}
	# Fix the logout shortcut problems, by moving the keybindings
	# into here, from control-center, fixes bug #52034
	epatch ${FILESDIR}/metacity-2-logout.patch

	# Disable animation while minimizing window, 
	# really visual speedup (Fixed by [e-mail])
        epatch ${FILESDIR}/metacity-2.10.0-animation.patch

	# Change default theme to more comfortable - need review
        #epatch ${FILESDIR}/metacity-2.3.987-default-theme.patch

	# Enables C-A-D keybindings
        epatch ${FILESDIR}/metacity-2.4.13.90-ctrlaltdel.patch

}

pkg_postinst() {

	gnome2_pkg_postinst

	einfo "Metacity & Xorg X11 with composite enabled may cause unwanted border effects"

}