# Copyright 1999-2018 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

PYTHON_REQ_USE="sqlite"
PYTHON_COMPAT=( python2_7 )
inherit cmake-utils python-single-r1

DESCRIPTION="The Zeek (Bro) Network Security Monitor"
HOMEPAGE="https://www.zeek.org"
SRC_URI="https://www.zeek.org/downloads/${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+broccoli +broctl curl debug geoip ipv6 jemalloc kerberos +python -ruby tcmalloc static-libs +tools"

RDEPEND="
	app-shells/bash:0
	dev-libs/openssl:0=
	net-analyzer/ipsumdump
	net-dns/bind-tools
	net-libs/libpcap
	sys-libs/zlib
	broctl? ( virtual/mta )
	curl? ( net-misc/curl )
	geoip? ( dev-libs/geoip )
	ipv6? ( net-analyzer/ipsumdump[ipv6] )
	jemalloc? ( dev-libs/jemalloc )
	kerberos? ( virtual/krb5 )
	python? ( ${PYTHON_DEPS} )
	ruby? ( >=dev-lang/ruby-1.8:= )
	tcmalloc? ( dev-util/google-perftools )
"
DEPEND="${RDEPEND}
	>=dev-lang/swig-3.0.3
	>=sys-devel/bison-2.5
"

REQUIRED_USE="
	broctl? ( python )
	python? ( ${PYTHON_REQUIRED_USE} )
"

pkg_setup() {
	use python && python-single-r1_pkg_setup
}

src_prepare() {
	# Disable shell script feature which sets interpreter to build time default
	find . -name "*.cmake" -exec sed -i -e "s:\${\${_shell}_interp}:/usr/bin/env ${EPYTHON}:g" {} + || die
	cmake-utils_src_prepare
}

src_configure() {
	local mycmakeargs=(
		-DENABLE_DEBUG=$(usex debug true false)
		-DENABLE_JEMALLOC=$(usex jemalloc true false)
		-DDISABLE_PERFTOOLS=$(usex tcmalloc false true)
		-DUSE_KRB5=$(usex kerberos true false)
		-DBUILD_STATIC_BROKER=$(usex static-libs true false)
		-DINSTALL_BROCCOLI=$(usex broccoli true false)
		-DINSTALL_BROCTL=$(usex broctl true false)
		-DINSTALL_AUX_TOOLS=$(usex tools true false)
		-DENABLE_MOBILE_IPV6=$(usex ipv6 true false)
		-DDISABLE_RUBY_BINDINGS=$(usex ruby false true)
		-DDISABLE_PYTHON_BINDINGS=$(usex python false true)
		-DBRO_LOG_DIR="/var/log/bro/"
		-DBRO_SPOOL_DIR="/var/spool/bro/"
		-DBRO_ETC_INSTALL_DIR="/etc/bro/"
		-DINSTALL_LIB_DIR="/usr/$(get_libdir)"
		-DPY_MOD_INSTALL_DIR="$(python_get_sitedir)"
	)

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	keepdir /var/log/bro /var/spool/bro/tmp
	# Doesn't exist
	rm -f "${ED}"/usr/share/broctl/scripts/broctl-config.sh
}