The ebuild (based on bin86-0.16.17.ebuild)

bin86-0.16.17.ebuild (text/plain), 912 bytes, created by Ingo Kemper on 2005-04-12 17:28:49 UTC

inherit toolchain-funcs eutils

DESCRIPTION="Assembler and loader used to create kernel bootsector"
HOMEPAGE="http://www.cix.co.uk/~mayday/"
SRC_URI="http://www.cix.co.uk/~mayday/dev86/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"
IUSE=""

RDEPEND="virtual/libc"
DEPEND="${RDEPEND}
	sys-apps/sed"

src_unpack() {
	unpack ${A}
	cd ${S}
	if [ "${ARCH}" = "amd64" ]; then
		epatch ${FILESDIR}/amd64liloSE.patch
		einfo "This is a special edition of bin86 without objdump86"
		einfo "to compile lilo on AMD64 systems."
	fi
	sed -i \
		-e 's:/man/man1:/share/man/man1:' \
		-e '/^INSTALL_OPTS/s:-s::' \
		Makefile || die "sed"
}

src_compile() {
	emake \
		PREFIX="/usr" \
		CC="$(tc-getCC)" \
		CFLAGS="${CFLAGS} -D_POSIX_SOURCE" \
		LDFLAGS="${LDFLAGS}" \
		|| die
}

src_install() {
	dodir /usr/bin /usr/share/man/man1
	make install PREFIX="${D}/usr" || die "install"
	dodoc README* ChangeLog
}