vulkan-tools-lunarg-1.1.92.0.ebuild

vulkan-tools-lunarg-1.1.92.0.ebuild (text/plain), 2.58 KB, created by Anton Romanov on 2018-12-21 08:49:02 UTC

# Copyright 1999-2018 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=6
PYTHON_COMPAT=( python3_{4,5,6} )

if [[ "${PV}" == "9999" ]]; then
	EGIT_REPO_URI="https://github.com/LunarG/VulkanTools.git"
	EGIT_SUBMODULES=()
	inherit git-r3
else
	EGIT_COMMIT="c6e45a0f05a7964e3405755f452100e89992d603"
	KEYWORDS="~amd64"
	SRC_URI="https://github.com/Lunarg/VulkanTools/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
	S="${WORKDIR}/VulkanTools-${EGIT_COMMIT}"
fi

inherit python-any-r1 cmake-multilib

DESCRIPTION="Additional Vulkan Tools and Utilities not include in dev-util/vulkan-tools"
HOMEPAGE="https://github.com/Lunarg/VulkanTools"

LICENSE="Apache-2.0"
SLOT="0"
IUSE="X wayland +vktrace"

DEPEND="${PYTHON_DEPS}
	dev-util/vulkan-headers
	media-libs/vulkan-layers:=[${MULTILIB_USEDEP},wayland?,X?]
	media-libs/vulkan-loader:=[${MULTILIB_USEDEP},wayland?,X?]
	wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
	vktrace? ( dev-libs/jsoncpp:=[${MULTILIB_USEDEP}] )
	X? (
		x11-libs/libX11:=[${MULTILIB_USEDEP}]
		x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
	   )"

# Vulkaninfo does not support wayland
REQUIRED_USE="|| ( X wayland )"

pkg_setup() {
	MULTILIB_CHOST_TOOLS=()

	MULTILIB_CHOST_TOOLS+=( /usr/bin/vktrace )
	MULTILIB_CHOST_TOOLS+=( /usr/bin/vkreplay )

	python-any-r1_pkg_setup
}

src_prepare () {
	epatch ${FILESDIR}/0000-system-jsoncpp.patch
	epatch ${FILESDIR}/0001-vkreplay_vkdisplay.patch
	epatch ${FILESDIR}/0002-vktrace_replay_cmake.patch

	eapply_user
}

multilib_src_configure() {
	local mycmakeargs=(
		-DCMAKE_SKIP_RPATH=True
		-DBUILD_CUBE=False
		-DBUILD_VULKANINFO=False
		-DBUILD_VIA=False
		-DBUILD_WSI_MIR_SUPPORT=False
		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
		-DGLSLANG_INSTALL_DIR="/usr"
		-DVULKAN_LOADER_INSTALL_DIR="/usr"
		-DVULKAN_VALIDATIONLAYERS_INSTALL_DIR="/usr"
		-DVULKAN_HEADERS_INSTALL_DIR="/usr"
		-DJSONCPP_INCLUDE_DIR="/usr/include/jsoncpp"
		-DBUILD_VKJSON=$(usex vktrace)
		-DBUILD_LAYERSVT=$(usex vktrace)
		-DBUILD_VKTRACE=$(usex vktrace)
		-DBUILD_LAYERMGR=False
	)
	# VKSON will also be needed for VIA

	# Upstream only supports one window system at a time
	# If X is set at all, even if wayland is set, use X
	#
	# If -cube and/or -vulkaninfo is set, the flags we set
	# are ignored, so we don't need to consider that
	if use X; then
		mycmakeargs+=(
			-DVKREPLAY_WSI_SELECTION="XCB"
		)
	fi

	if ! use X && use wayland; then
		mycmakeargs+=(
			-DVKREPLAY_WSI_SELECTION="WAYLAND"
		)
	fi

	cmake-utils_src_configure
}

multilib_src_install() {
	cmake-utils_src_install
}