# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=7
inherit elisp-common flag-o-matic

DESCRIPTION="GNU Smalltalk"
HOMEPAGE="http://smalltalk.gnu.org"
SRC_URI="mirror://gnu/smalltalk/smalltalk-${PV}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="tk readline emacs gtk gmp"

RDEPEND="
	app-arch/zip
	sys-libs/gdbm:0=
	sys-apps/debianutils
	dev-libs/libsigsegv
	virtual/libffi:0=
	emacs? ( virtual/emacs )
	readline? ( sys-libs/readline:0= )
	tk? ( dev-lang/tk:0= )
	gtk? ( x11-libs/gtk+:2 )
	gmp? ( dev-libs/gmp:0= )
"
DEPEND="${RDEPEND}"

S="${WORKDIR}/smalltalk-${PV}"

SITEFILE="50gnu-smalltalk-gentoo.el"

PATCHES=(
	# fix misuse of the Tcl API, bug 492710
	"${FILESDIR}"/${PN}-3.2_use-result.patch
)

src_configure() {
	replace-flags '-O3' '-O2'
	append-flags $(test-flags -no-pie) #645690
	append-ldflags $(test-flags -no-pie) #645690
	econf \
		--disable-static \
		--libdir=/usr/$(get_libdir) \
		--with-system-libsigsegv \
		--with-system-libffi \
		--with-system-libltdl \
		$(use_with emacs emacs) \
		$(use_with readline readline) \
		$(use_with gmp gmp) \
		$(use_with tk tcl /usr/$(get_libdir)) \
		$(use_with tk tk /usr/$(get_libdir)) \
		$(use_enable gtk gtk)
}

src_compile() {
	emake
	use emacs && elisp-compile *.el
}

src_install() {
	emake DESTDIR="${D}" install
	dodoc AUTHORS COPYING* ChangeLog NEWS README THANKS TODO

	if use emacs; then
		elisp-install "${PN}" *.el *.elc
		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
	fi

	fperms 0444 /usr/share/smalltalk/packages.xml

	# Fix QA notice complaining about dangling symlink.
	# There's probably a better way to do this but I couldn't find it.
	pushd "${D}"/usr/share/man/man1
	rm gst-reload.1
	ln -s $(find . -name "gst-load*") gst-reload.1
	popd

	find "${D}" -name '*.la' -delete || die
}

pkg_postinst() {
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}