tpm2-tss-2.0.1.ebuild

tpm2-tss-2.0.1.ebuild (text/plain), 1.37 KB, created by Sebastian Hamann on 2018-10-01 18:10:01 UTC

# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit linux-info

DESCRIPTION="TCG Trusted Platform Module 2.0 Software Stack"
HOMEPAGE="https://github.com/tpm2-software/tpm2-tss"
SRC_URI="https://github.com/tpm2-software/${PN}/releases/download/${PV}/${P}.tar.gz"

LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc static-libs"

DEPEND="dev-libs/libgcrypt
	virtual/pkgconfig
	doc? ( app-doc/doxygen )"
RDEPEND="${DEPEND}"

pkg_setup() {
	linux-info_pkg_setup
	local tpm_kernel_version tpm_kernel_present
	kernel_is ge 4 12 0 && tpm_kernel_version="yes"
	if linux_config_exists; then
		linux_chkconfig_present TCG_TPM && tpm_kernel_present="yes"
	else
		ewarn "No kernel configuration could be found."
	fi
	if [[ -n "${tpm_kernel_present}" ]]; then
		einfo "Good, you seem to have in-kernel TPM support."
	elif [[ -n "${tpm_kernel_version}" ]]; then
		eerror
		eerror "To use this package, you will have to activate TPM support"
		eerror "in your kernel configuration. That's at least CONFIG_TCG_TPM,"
		eerror "plus probably a chip specific driver (like CONFIG_TCG_TIS)."
		eerror
	else
		eerror
		eerror "To use this package, you must install a kernel newer than"
		eerror "4.12.0 and enable TPM support."
		eerror
	fi
}

src_configure() {
	econf \
		$(use_enable doc doxygen-doc) \
		$(use_enable static-libs static)
}