mures-0.5.ebuild

mures-0.5.ebuild (text/plain), 2.40 KB, created by Alexandru Toma on 2005-03-27 03:39:27 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

DESCRIPTION="A clone of Sega's Chu Chu Rocket"
HOMEPAGE="http://mures.sourceforge.net/"
SRC_URI="mirror://sourceforge/mures/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86"
IUSE="opengl"

DEPEND=">=media-libs/libsdl-1.2.3
	>=media-libs/sdl-image-1.2.3
	>=media-libs/sdl-net-1.2.5
	>=media-libs/sdl-ttf-2.0.6
	opengl? ( virtual/opengl )"

DEST_DIR="${GAMES_DATADIR}/${PN}"

src_unpack() {
	unpack ${A}
	cd ${S}

	# Disable OpenGL support if USE flag is not set
	if use !opengl ; then
		einfo "Disabling OpenGL"
		sed -i \
			-e 's: -DHAVE_GL::' \
			-e 's: -lGL::' \
			configure.in || die "sed configure.in failed"
		sed -i -e 's:./configure \$\*::' \
			autogen.sh || die "sed autogen.sh failed"
	fi

	cd src

	# Apply savegame patch. Game will be saved in ~/saved.mus
	epatch ${FILESDIR}/${P}-save.patch

	# Apply screenshot save patch. It will be saved as ~/mures_shot.bmp
	epatch ${FILESDIR}/${P}-screenshot.patch

	# Modify game data & scrips path
	sed -i \
		-e "s:gui/:${DEST_DIR}/gui/:" \
		-e "s:sounds/:${DEST_DIR}/sounds/:" \
		gui.c || die "sed gui.c failed"
	sed -i \
		-e "s:images/:${DEST_DIR}/images/:" \
		-e "s:textures/:${DEST_DIR}/textures/:" \
		go_sdl.c || die "sed go_sdl.c failed"
	sed -i \
		-e "s:textures/:${DEST_DIR}/textures/:" \
		go_gl.c || die "sed go_gl.c failed"
	sed -i \
		-e "s:input.lua:${DEST_DIR}/input.lua:" \
		gi_sdl.c || die "sed gi_sdl.c failed"
	sed -i \
		-e "s:images/:${DEST_DIR}/images/:" \
		anim.c output.c || die "sed anim.c output.c failed"
	sed -i \
		-e "s:maps/:${DEST_DIR}/maps/:" \
		load_maps.lua || die "sed load_maps.lua failed"
	sed -i \
		-e "s:sounds/:${DEST_DIR}/sounds/:" \
		audio_sdl.c || die "sed audio_sdl.c failed"
	sed -i \
		-e "s:load_maps.lua:${DEST_DIR}/load_maps.lua:" \
		map.c || die "sed map.c failed"
}

src_compile() {
	if use !opengl ; then
		./autogen.sh
	fi
	egamesconf || die "egamesconf failed"
	emake || die "emake failed"
}

src_install() {
	local f

	dodoc README TODO ChangeLog AUTHORS

	cd src
	dogamesbin mures || die "dogamesbin failed"

	for f in gui images sounds textures maps/battle maps/puzzle
	do
		# Remove makefiles before installation
		rm ${f}/Makefile*
		insinto ${DEST_DIR}/${f}
		doins ${f}/* || die "doins ${f} failed"
	done

	insinto ${DEST_DIR}
	doins *.lua || die "doins failed"

	prepgamesdirs
}