astroid-9999.ebuild

astroid-9999.ebuild (text/plain), 1.52 KB, created by Alex Xu (Hello71) on 2018-07-19 18:48:15 UTC

# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

: "${CMAKE_MAKEFILE_GENERATOR:=ninja}"

inherit cmake-utils git-r3 virtualx

DESCRIPTION="lightweight graphical threads-with-tags style email client for notmuch"
HOMEPAGE="https://github.com/astroidmail/astroid"
EGIT_REPO_URI="https://github.com/astroidmail/astroid.git"

LICENSE="GPL-3+"
SLOT="0"
KEYWORDS=""
IUSE="+embedded-editor +plugins profile +terminal test"

RDEPEND="
	plugins? (
		dev-libs/gobject-introspection
		>=dev-libs/libpeas-1.0.0
		dev-libs/gmime:2.6[vala]
	)
	terminal? (
		x11-libs/vte:2.91
	)
	dev-cpp/glibmm:2
	>=dev-cpp/gtkmm-3.10:3.0
	dev-libs/boost
	>=dev-libs/gmime-2.6.0:2.6
	dev-libs/libsass
	>=dev-libs/protobuf-3.6.0:=
	>=net-libs/webkit-gtk-2.20:4
	net-mail/notmuch
"
DEPEND="${RDEPEND}
	test? (
		${VIRTUALX_DEPEND}
		app-crypt/gnupg
	)
	virtual/pkgconfig
"

src_prepare() {
	if ! use test; then
		sed -i -e '/enable_testing/d;/add_subdirectory.*tests.*/d' CMakeLists.txt
		rm -rf tests
	fi

	if use terminal; then
		sed -i -e '/pkg_check_modules.*VTE2/s/VTE2/VTE2 REQUIRED/' CMakeLists.txt
	fi

	cmake-utils_src_prepare
}

src_configure() {
	local mycmakeargs=(
		-DDISABLE_EMBEDDED_EDITOR=$(usex embedded-editor OFF ON)
		-DDISABLE_TERMINAL=$(usex terminal OFF ON)
		-DDISABLE_PLUGINS=$(usex plugins OFF ON)
		-DENABLE_PROFILING=$(usex profile ON OFF)
	)

	cmake-utils_src_configure
}

src_test() {
	local myctestargs=(
		-E markdown # requires unpackaged "marked" program
	)

	virtx cmake-utils_src_test
}