# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/rosegarden/rosegarden-4.1.0.ebuild,v 1.2 2005/03/09 21:49:24 luckyduck Exp $

inherit eutils flag-o-matic kde
need-kde 3.0

IUSE="alsa jack"

MY_PV="${PV/_rc*/}"
MY_PV="${MY_PV/./-}"
MY_P="${PN}-${MY_PV}"
S="${WORKDIR}/${MY_P}"

DESCRIPTION="MIDI and audio sequencer and notation editor."
HOMEPAGE="http://www.rosegardenmusic.com/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"

DEPEND="${DEPEND}
	alsa? ( media-libs/alsa-lib )
	jack? ( media-libs/alsa-lib media-sound/jack-audio-connection-kit )
	media-libs/libmad
	>=media-libs/ladspa-sdk-1.0
	>=media-libs/ladspa-cmt-1.14"

pkg_setup() {
	if ! use alsa && ! use arts; then
		die "You must select at least one of arts or alsa support."
	fi
	
	if use alsa && use arts; then
		die "You can't select both alsa and arts."
	fi
}

src_unpack() {
	kde_src_unpack

	cd ${S}
	epatch ${FILESDIR}/${PV}-dssi.patch
}

src_compile() {
	strip-flags -fvisibility-inlines-hidden

	myconf="${myconf}
		$(use_with arts)
		$(use_with alsa)
		$(use_with jack)
		--with-ladspa"

	kde_src_compile
}