DRAFT: pacman-5.1.0

file_659474.txt (text/plain), 2.90 KB, created by Nils Freydank on 2018-07-02 16:31:43 UTC

# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=7

PYTHON_COMPAT=( python2_7 python3_{5,6} )

inherit autotools

DESCRIPTION="Archlinux's binary package manager"
HOMEPAGE="https://archlinux.org/pacman/"

if [[ ${PV} == *9999 ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://git.archlinux.org/pacman.git"
else
	SRC_URI="https://sources.archlinux.org/other/pacman/${P}.tar.gz"
	# Do *not* re-add ~x86!
	# https://www.archlinux.org/news/phasing-out-i686-support/
	KEYWORDS="~amd64"
fi

LICENSE="GPL-2"
SLOT="0/10"

# TODO: Checkme!
IUSE="curl debug doc +gpg test"
COMMON_DEPEND="app-arch/libarchive:=[lzma]
	gpg? ( >=app-crypt/gpgme-1.4.0:= )
	dev-libs/openssl:0=
	curl? ( net-misc/curl )
	virtual/libiconv
	virtual/libintl"
RDEPEND="${COMMON_DEPEND}"

# TODO: Checkme!
DEPEND="${COMMON_DEPEND}
	app-text/asciidoc
	doc? ( app-doc/doxygen )
	test? ( sys-apps/fakeroot
	sys-apps/fakechroot )"

# workaround until tests are fixed/sorted out
RESTRICT="test"

src_prepare() {
	# Remove a line that adds "-Werror" in ./configure when
	# "--enable-debug" is passed:
	sed -i -e '/-Werror/d' configure.ac || die

	default
	eautoreconf
}

src_configure() {
	local myeconfargs=(
		--localstatedir=/var
		# Help protect user from shooting his/her Gentoo installation
		# in its foot.
		--with-root-dir="${EPREFIX}/var/chroot/archlinux"
		$(use_enable debug)
		# full doc with doxygen
		$(use_enable doc doxygen)
		$(use_with curl libcurl)
		$(use_with gpg gpgme)
	)

	if [[ ${PV} == *9999 ]]; then
		myeconfargs+=( --enable-git-version)
	else
		myeconfargs+=( --disable-git-version )
	fi

	econf "${myeconfargs[@]}"
}

src_install() {
	dodir /etc/pacman.d/
	# create /var/chroot/archlinux
	# see bug #631754
	dodir /var/chroot/archlinux

	default

	# avoid creating stuff inside /var/cache/
	# see bug #633742 for more information
	rm -r "${D}"/var/cache/pacman
}

pkg_postinst() {
	einfo ""
	einfo "The default root dir was set to ${EPREFIX}/var/chroot/archlinux"
	einfo "to avoid breaking Gentoo systems due to oscitancy."
	einfo "If you prefer another directory, take a look at"
	einfo "pacman’s parameter -r|--root)."
	einfo ""
	einfo "You will need to setup at least one mirror in /etc/pacman.d/mirrorlist."
	einfo "Please generate it manually according to the Archlinux documentation:"
	einfo "https://wiki.archlinux.org/index.php/Mirror"
	einfo ""
	ewarn "Archlinux as the main pacman using party and main developer group"
	ewarn "dropped support for x86 (i686 called there) entirely in Nov 2017."
	ewarn "Please keep this in mind when setting up new systems."
	ewarn "For more details see"
	ewarn "https://www.archlinux.org/news/phasing-out-i686-support"
	einfo ""
	ewarn "Note that the helper scripts were moved to the pacman-contrib project."
	ewarn "You need to install manually for now."
}