[patch] qtwebkit-5.212.0_pre20180120.ebuild.diff

qtwebkit-5.212.0_pre20180120.ebuild.diff (text/plain), 6.25 KB, created by Andreas Sturmlechner on 2018-06-30 15:58:55 UTC

--- a/dev-qt/qtwebkit/qtwebkit-5.9.1.ebuild	2018-06-24 23:10:01.410355469 +0200
+++ b/dev-qt/qtwebkit/qtwebkit-5.212.0_pre20180120.ebuild	2018-06-30 17:55:38.203012839 +0200
@@ -2,46 +2,49 @@
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
+
+COMMIT=72cfbd7664f21fcc0e62b869a6b01bf73eb5e7da
+CMAKE_MAKEFILE_GENERATOR="ninja"
 PYTHON_COMPAT=( python2_7 )
-QT_MIN_VER="5.9.1:5"
-inherit python-any-r1 qt5-build
+USE_RUBY="ruby23 ruby24 ruby25"
+inherit check-reqs cmake-utils flag-o-matic python-any-r1 qmake-utils ruby-single toolchain-funcs
 
 DESCRIPTION="WebKit rendering library for the Qt5 framework (deprecated)"
+HOMEPAGE="https://www.qt.io/"
+SRC_URI="http://code.qt.io/cgit/qt/${PN}.git/snapshot/${COMMIT}.tar.gz -> ${P}.tar.gz"
 
-if [[ ${QT5_BUILD_TYPE} == release ]]; then
-	KEYWORDS="amd64 ~arm ~arm64 ~ppc ppc64 x86"
-fi
-
-# TODO: qttestlib
-
-IUSE="geolocation gstreamer gles2 +jit multimedia opengl orientation printsupport qml test webchannel webp"
-REQUIRED_USE="?? ( gstreamer multimedia )"
+LICENSE="BSD LGPL-2+"
+SLOT="5/5.212"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="geolocation gles2 +gstreamer +hyphen +jit multimedia nsplugin opengl orientation +printsupport qml webp X"
+
+REQUIRED_USE="
+	nsplugin? ( X )
+	qml? ( opengl )
+	?? ( gstreamer multimedia )
+"
 
+QT_MIN_VER="5.9.1:5"
+# Dependencies found at Source/cmake/OptionsQt.cmake
 RDEPEND="
 	dev-db/sqlite:3
 	dev-libs/icu:=
-	>=dev-libs/leveldb-1.18-r1:=
 	dev-libs/libxml2:2
 	dev-libs/libxslt
-	>=dev-qt/qtcore-${QT_MIN_VER}[icu]
+	>=dev-qt/qtcore-${QT_MIN_VER}
 	>=dev-qt/qtgui-${QT_MIN_VER}
 	>=dev-qt/qtnetwork-${QT_MIN_VER}
-	>=dev-qt/qtsql-${QT_MIN_VER}
 	>=dev-qt/qtwidgets-${QT_MIN_VER}
-	media-libs/fontconfig:1.0
 	media-libs/libpng:0=
-	>=sys-libs/zlib-1.2.5
 	virtual/jpeg:0
-	virtual/opengl
-	x11-libs/libX11
-	x11-libs/libXcomposite
-	x11-libs/libXrender
 	geolocation? ( >=dev-qt/qtpositioning-${QT_MIN_VER} )
 	gstreamer? (
 		dev-libs/glib:2
 		media-libs/gstreamer:1.0
 		media-libs/gst-plugins-base:1.0
+		media-libs/gst-plugins-bad:1.0
 	)
+	hyphen? ( dev-libs/hyphen )
 	multimedia? ( >=dev-qt/qtmultimedia-${QT_MIN_VER}[widgets] )
 	opengl? (
 		>=dev-qt/qtgui-${QT_MIN_VER}[gles2=]
@@ -49,71 +52,89 @@
 	)
 	orientation? ( >=dev-qt/qtsensors-${QT_MIN_VER} )
 	printsupport? ( >=dev-qt/qtprintsupport-${QT_MIN_VER} )
-	qml? ( >=dev-qt/qtdeclarative-${QT_MIN_VER} )
-	webchannel? ( >=dev-qt/qtwebchannel-${QT_MIN_VER} )
+	qml? (
+		>=dev-qt/qtdeclarative-${QT_MIN_VER}
+		>=dev-qt/qtwebchannel-${QT_MIN_VER}[qml]
+	)
 	webp? ( media-libs/libwebp:0= )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXcomposite
+		x11-libs/libXrender
+	)
 "
+
+# Need real bison, not yacc
 DEPEND="${RDEPEND}
 	${PYTHON_DEPS}
-	dev-lang/ruby
+	${RUBY_DEPS}
+	dev-lang/perl
 	dev-util/gperf
-	sys-devel/bison
+	>=sys-devel/bison-2.4.3
 	sys-devel/flex
-	virtual/rubygems
-	test? ( >=dev-qt/qttest-${QT_MIN_VER} )
+	virtual/pkgconfig
 "
 
-PATCHES=(
-	"${FILESDIR}/${PN}-5.4.2-system-leveldb.patch"
-)
-
-src_prepare() {
-	# ensure bundled library cannot be used
-	rm -r Source/ThirdParty/leveldb || die
-
-	# force using system library
-	sed -i -e 's/qtConfig(system-jpeg)/true/' \
-		-e 's/qtConfig(system-png)/true/' \
-		Tools/qmake/mkspecs/features/features.prf || die
-
-	# bug 466216
-	sed -i -e '/CONFIG +=/s/rpath//' \
-		Source/WebKit/qt/declarative/{experimental/experimental,public}.pri \
-		Tools/qmake/mkspecs/features/{force_static_libs_as_shared,unix/default_post}.prf \
-		|| die
-
-	qt_use_disable_config opengl opengl Tools/qmake/mkspecs/features/features.prf
-
-	qt_use_disable_mod geolocation positioning Tools/qmake/mkspecs/features/features.prf
-	qt_use_disable_mod multimedia multimediawidgets Tools/qmake/mkspecs/features/features.prf
-	qt_use_disable_mod orientation sensors Tools/qmake/mkspecs/features/features.prf
-	qt_use_disable_mod printsupport printsupport Tools/qmake/mkspecs/features/features.prf
-	qt_use_disable_mod qml quick Tools/qmake/mkspecs/features/features.prf
-	qt_use_disable_mod webchannel webchannel \
-		Source/WebKit2/Target.pri \
-		Source/WebKit2/WebKit2.pri
+CHECKREQS_DISK_BUILD="16G" # Debug build requires much more see bug #417307
 
-	if ! use gstreamer; then
-		PATCHES+=("${FILESDIR}/${PN}-5.8.0-disable-gstreamer.patch")
+S="${WORKDIR}/${COMMIT}"
+
+PATCHES=( "${FILESDIR}/${P}-functional.patch" )
+
+_check_reqs() {
+	if [[ ${MERGE_TYPE} != "binary" ]] && is-flagq "-g*" && ! is-flagq "-g*0" ; then
+		einfo "Checking for sufficient disk space to build ${PN} with debugging CFLAGS"
+		check-reqs_pkg_pretend
 	fi
+}
+
+pkg_pretend() {
+	_check_reqs
+}
 
-	# bug 562396
-	use jit || PATCHES+=("${FILESDIR}/${PN}-5.5.1-disable-jit.patch")
+pkg_setup() {
+	_check_reqs
+	python-any-r1_pkg_setup
+}
 
-	use webp || sed -i -e '/config_libwebp: WEBKIT_CONFIG += use_webp/d' \
-		Tools/qmake/mkspecs/features/features.prf || die
+src_configure() {
+	# Respect CC, otherwise fails on prefix #395875
+	tc-export CC
+
+	# Multiple rendering bugs on youtube, github, etc without this, bug #547224
+	append-flags $(test-flags -fno-strict-aliasing)
+
+	local mycmakeargs=(
+		-DPORT=Qt
+		-DENABLE_API_TESTS=OFF
+		-DENABLE_GEOLOCATION=$(usex geolocation)
+		-DUSE_GSTREAMER=$(usex gstreamer)
+		-DENABLE_JIT=$(usex jit)
+		-DUSE_QT_MULTIMEDIA=$(usex multimedia)
+		-DENABLE_NETSCAPE_PLUGIN_API=$(usex nsplugin)
+		-DENABLE_OPENGL=$(usex opengl)
+		-DENABLE_DEVICE_ORIENTATION=$(usex orientation)
+		-DENABLE_WEBKIT2=$(usex qml)
+		$(cmake-utils_use_find_package webp WebP)
+		-DENABLE_X11_TARGET=$(usex X)
+	)
 
-	# bug 458222
-	sed -i -e '/SUBDIRS += examples/d' Source/QtWebKit.pro || die
+	if has_version "virtual/rubygems[ruby_targets_ruby25]"; then
+		mycmakeargs+=( -DRUBY_EXECUTABLE=$(type -P ruby25) )
+	elif has_version "virtual/rubygems[ruby_targets_ruby24]"; then
+		mycmakeargs+=( -DRUBY_EXECUTABLE=$(type -P ruby24) )
+	else
+		mycmakeargs+=( -DRUBY_EXECUTABLE=$(type -P ruby23) )
+	fi
 
-	qt5-build_src_prepare
+	cmake-utils_src_configure
 }
 
 src_install() {
-	qt5-build_src_install
+	cmake-utils_src_install
 
 	# bug 572056
-	if [[ ! -f ${D%/}${QT5_LIBDIR}/libQt5WebKit.so ]]; then
+	if [[ ! -f ${D%/}$(qt5_get_libdir)/libQt5WebKit.so ]]; then
 		eerror "${CATEGORY}/${PF} could not build due to a broken ruby environment."
 		die 'Check "eselect ruby" and ensure you have a working ruby in your $PATH'
 	fi