# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit eutils scons-utils toolchain-funcs

DESCRIPTION="A Free Toolkit for developing mapping applications"
HOMEPAGE="http://www.mapnik.org/"
SRC_URI="https://github.com/mapnik/mapnik/releases/download/v${PV}/mapnik-v${PV}.tar.bz2 -> ${P}.tar.bz2"
S="${WORKDIR}/mapnik-v${PV}"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64"
IUSE="cairo debug doc gdal postgres sqlite svg +osmfonts"

RDEPEND="
        >=dev-libs/boost-1.56[threads]
        >=dev-libs/icu-42
        sys-libs/zlib
        media-libs/freetype:2
        >=media-libs/harfbuzz-0.9.34
        dev-libs/libxml2
        >=media-libs/libpng-1.2
        media-libs/tiff:0=
        virtual/jpeg:0=
        media-libs/libwebp
        sci-libs/proj
        osmfonts? ( media-fonts/dejavu )
        osmfonts? ( media-fonts/noto )
        osmfonts? ( media-fonts/noto-cjk )
        osmfonts? ( media-fonts/unifont )
        x11-libs/agg[truetype]
        cairo? (
                >=x11-libs/cairo-1.6.0
                dev-cpp/cairomm
        )
        postgres? ( >=dev-db/postgresql-9.5.5:* )
        gdal? ( >=sci-libs/gdal-2.0.2 )
        sqlite? ( dev-db/sqlite:3 )
        svg? (
                >=x11-libs/cairo-1.6.0
                dev-cpp/cairomm
        )"
DEPEND="${RDEPEND}
        >=sys-devel/gcc-4.8.5-r1
        dev-lang/python:2.7
    dev-util/pkgconfig
"

PATCHES=(
        "${FILESDIR}/${PN}-2.2.0-configure-only-once.patch"
        "${FILESDIR}/${PN}-2.2.0-dont-run-ldconfig.patch"
        "${FILESDIR}/${PN}-3.0.18-scons.patch"
)

src_prepare() {
        default

        # do not version epidoc data
        sed -i \
                -e 's:-`mapnik-config --version`::g' \
                utils/epydoc_config/build_epydoc.sh || die

        # force user flags, optimization level
        sed -i -e "s:\-O%s:%s:" \
                -i -e "s:env\['OPTIMIZATION'\]:'${CXXFLAGS}':" \
                SConstruct || die
}

src_configure() {
# INPUT_PLUGINS: Input drivers to include
#    (all|none|comma-separated list of names)
#    allowed names: raster postgis pgraster shape topojson gdal sqlite geojson ogr csv
#    default: raster,postgis,pgraster,shape,topojson,gdal,sqlite,geojson,ogr,csv
        local PYTHONCMD="$(which python2.7)"
        local PLUGINS=raster,shape,topojson,geojson,csv
        use gdal && PLUGINS+=,gdal,ogr
        use postgres && PLUGINS+=,postgis,pgraster
        use sqlite && PLUGINS+=,sqlite

        MYSCONS=(
                "CC=$(tc-getCC)"
                "CXX=$(tc-getCXX)"
                "INPUT_PLUGINS=${PLUGINS}"
                "PREFIX=/usr"
                "DESTDIR=${D}"
                "PYTHON=$PYTHONCMD"
                "XMLPARSER=libxml2"
                "LINKING=shared"
                "RUNTIME_LINK=shared"
                "PROJ_INCLUDES=/usr/include"
                "PROJ_LIBS=/usr/$(get_libdir)"
                "LIBDIR_SCHEMA=$(get_libdir)"
        "FREETYPE_INCLUDES=/usr/include/freetype2"
                "FREETYPE_LIBS=/usr/$(get_libdir)"
                "XML2_INCLUDES=/usr/include/libxml2"
                "XML2_LIBS=/usr/$(get_libdir)"
                "SYSTEM_FONTS=/usr/share/fonts"
                CAIRO="$(usex cairo 1 0)"
                SVG_RENDERER="$(usex svg 1 0)"
                SVG2PNG="$(usex svg 1 0)"
                DEBUG="$(usex debug 1 0)"
                XML_DEBUG="$(usex debug 1 0)"
                DEMO="$(usex doc 1 0)"
                SAMPLE_INPUT_PLUGINS="$(usex doc 1 0)"
                "CUSTOM_LDFLAGS=${LDFLAGS}"
                "CUSTOM_LDFLAGS+=-L${ED}/usr/$(get_libdir)"
        )
        escons "${MYSCONS[@]}" configure
}

src_compile() {
        escons "${MYSCONS[@]}"
}

src_install() {
        escons "${MYSCONS[@]}" DESTDIR="${D}" install

        dodoc AUTHORS.md README.md CHANGELOG.md
}

pkg_postinst() {
        elog ""
        elog "See the home page or wiki (https://github.com/mapnik/mapnik/wiki) for more info"
        elog "or the installed examples for the default mapnik ogcserver config."
        elog ""
        elog "The osmfonts use flag adds fonts commonly used with openstreetmap styles as"
        elog "runtime dependencies."
        elog ""
}