seahorse-9999.ebuild

seahorse-9999.ebuild (text/plain), 1.58 KB, created by cyrillic on 2018-05-31 18:36:49 UTC

# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit gnome2 gnome-meson vala
if [[ ${PV} = 9999 ]]; then
	inherit gnome2-live
fi

DESCRIPTION="A GNOME application for managing encryption keys"
HOMEPAGE="https://wiki.gnome.org/Apps/Seahorse"

LICENSE="GPL-2+ FDL-1.1+"
SLOT="0"
IUSE="keyservers key-sharing ldap"
if [[ ${PV} = 9999 ]]; then
	KEYWORDS=""
else
	KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
fi

COMMON_DEPEND="
	>=app-crypt/gcr-3.11.91:=
	>=dev-libs/glib-2.44:2
	>=x11-libs/gtk+-3.22:3
	>=app-crypt/libsecret-0.16
	>=net-libs/libsoup-2.33.92:2.4
	x11-misc/shared-mime-info

	net-misc/openssh
	>=app-crypt/gpgme-1.7.0
	>=app-crypt/gnupg-2.0.12

	ldap? ( net-nds/openldap:= )
	key-sharing? ( >=net-dns/avahi-0.6:= )
"
DEPEND="${COMMON_DEPEND}
	$(vala_depend)
	app-text/yelp-tools
	dev-util/gdbus-codegen
	>=dev-util/intltool-0.35
	dev-util/itstool
	sys-devel/gettext
	virtual/pkgconfig
"
# Need seahorse-plugins git snapshot
RDEPEND="${COMMON_DEPEND}
	!<app-crypt/seahorse-plugins-2.91.0_pre20110114
"
src_prepare() {
	vala_src_prepare
	gnome-meson_src_prepare
}

src_configure() {
	local emesonargs=(
		-Dpgp-support=true
		-Dcheck-compatible-gpg=false
		-Dpkcs11-support=true
		-Dhkp-support=true
		$(meson_use ldap ldap-support)
		$(meson_use keyservers keyservers-support)
		$(meson_use key-sharing)
	)

	gnome-meson_src_configure
}

src_compile() {
	gnome-meson_src_compile
}

src_install() {
	gnome-meson_src_install
}

pkg_postinst() {
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}