xfwm4-9999.ebuild

xfwm4-9999.ebuild (text/plain), 2.03 KB, created by Derk W te Bokkel on 2018-05-11 13:22:13 UTC

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6
inherit git-r3 libtool

AUTOTOOLS_AUTO_DEPEND=yes

DESCRIPTION="Window manager for the Xfce desktop environment"
HOMEPAGE="https://www.xfce.org/projects/"
EGIT_REPO_URI="https://git.xfce.org/xfce/${PN}"
#SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="opengl startup-notification +xcomposite xpresent"

RDEPEND="dev-libs/dbus-glib:=
	>=dev-libs/glib-2.20:=
	>=x11-libs/gtk+-3.20:3=
	x11-libs/libX11:=
	x11-libs/libXext:=
	x11-libs/libXrandr:=
	x11-libs/libXrender:=
	x11-libs/pango:=
	>=x11-libs/libwnck-2.30:1=
	>=xfce-base/libxfce4util-4.10:=
	>=xfce-base/libxfce4ui-4.11:=
	>=xfce-base/xfconf-4.10:=
	opengl? ( media-libs/libepoxy:=[X(+)] )
	startup-notification? ( x11-libs/startup-notification:= )
	xpresent? ( x11-libs/libXpresent )
	xcomposite? (
		x11-libs/libXcomposite:=
		x11-libs/libXdamage:=
		x11-libs/libXfixes:=
		)"

# libICE/liBSM: not really used anywhere but checked by configure
#   https://bugzilla.xfce.org/show_bug.cgi?id=11914
DEPEND="${RDEPEND}
	dev-util/gtk-doc
	>=dev-util/xfce4-dev-tools-4.12
	dev-util/intltool
	sys-devel/gettext
	x11-libs/libICE
	x11-libs/libSM
	xfce-base/exo
	virtual/pkgconfig"

DOCS=( AUTHORS COMPOSITOR NEWS README TODO )

src_configure() {
	local myconf=(
		--docdir="${EPREFIX}"/usr/share/doc/${PF}
		#$(use_enable dri libdrm)
		$(use_enable opengl epoxy)
		$(use_enable startup-notification)
		--enable-xsync
		--enable-render
		--enable-randr
		--enable-gtk3
		$(use_enable xpresent)
		$(use_enable xcomposite compositor)
		# have to add both these for xfce-base-dev ebuilds else they fail to build
		--enable-debug=minimum
		--enable-maintainer-mode
	)

	econf "${myconf[@]}"
}

src_prepare() {
	default
	## xfce4-dev-tools routines are called by autogen.sh script to prepare source code for building
	./autogen.sh
	elibtoolize
}

src_install() {
	emake DESTDIR="${D}" "$@" install

	einstalldocs
	find "${D}" -name '*.la' -delete || die
}