# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6
inherit cmake-utils flag-o-matic

DESCRIPTION="A Sega Saturn emulator"
HOMEPAGE="http://yabause.org/"
SRC_URI="https://download.tuxfamily.org/${PN}/releases/${PV}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="openal opengl +pic qt5 sdl"

RDEPEND="
	x11-libs/libXrandr
	openal? ( media-libs/openal )
	opengl? (
		media-libs/freeglut
		virtual/glu
		virtual/opengl
	)
	qt5? (
		dev-qt/qtcore:5
		dev-qt/qtwidgets:5
		opengl? ( dev-qt/qtopengl:5 )
	)
	!qt5? (
		dev-libs/glib:2
		x11-libs/gtk+:2
		x11-libs/gtkglext
	)
	sdl? ( media-libs/libsdl2[opengl?,video] )"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

PATCHES=( "${FILESDIR}/${P}-RWX.patch" )

src_configure() {
	if ! use pic; then
		append-cflags "-no-pie"
		append-ldflags "-no-pie"
	fi
	local mycmakeargs=(
		-DYAB_OPTIMIZATION=""
		-DYAB_WANT_OPENGL=$(usex sdl)
		-DYAB_WANT_OPENAL=$(usex openal)
		-DYAB_WANT_OPENGL=$(usex opengl)
		-DSH2_DYNAREC=$(usex !pic)
		-DYAB_PORTS=$(usex qt5 "qt" "gtk")
	)
	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	dodoc AUTHORS ChangeLog README
}

pkg_postinst() {
	echo "Try 'export MESA_GL_VERSION_OVERRIDE=3.0' if you can't use"
	! use pic && ewarn "You are warned once again compiling with PIE is gentoo default"
}