# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=6

inherit fdo-mime

DESCRIPTION="A music notation editor"
HOMEPAGE="http://www.denemo.org/"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"

LICENSE="GPL-3 OFL-1.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="alsa aubio coverage debug doc evince fluidsynth gtk2 guile jack nls portmidi rubberband static-libs test"

COMMON_DEPEND="
	evince? ( >=app-text/evince-3 )
	dev-libs/libxml2:2
	guile? ( >=dev-scheme/guile-2.0 )
	gnome-base/librsvg:2
	media-libs/fontconfig:1.0
	>=media-libs/libsmf-1.3
	media-libs/libsndfile
	gtk2? ( x11-libs/gtk+:2 )
	!gtk2? ( x11-libs/gtk+:3 )
	x11-libs/gtksourceview:3.0
	alsa? ( media-libs/alsa-lib )
	jack? ( virtual/jack )
	fluidsynth? ( media-sound/fluidsynth )
	aubio? ( media-libs/aubio )
	sci-libs/fftw:3.0
	media-libs/libsamplerate
	portmidi? ( media-libs/portmidi )
	rubberband? ( media-libs/rubberband )"

RDEPEND="${COMMON_DEPEND}
	media-sound/lilypond"
DEPEND="${COMMON_DEPEND}
	sys-devel/flex
	virtual/pkgconfig
	virtual/yacc
	nls? ( sys-devel/gettext )
	doc? ( dev-util/gtk-doc )"

DOCS=( AUTHORS ChangeLog docs/{DESIGN{,.lilypond},GOALS,TODO} NEWS )

src_prepare() {
	eapply "${FILESDIR}/${P}-no-portaudio-fix.patch"
	sed -ie '/^Categories=/s/GNOME\;/GNOME\;GTK\;/' pixmaps/denemo.desktop
	default
}

# Configuration notes:
# --enable-mem relies on electric fence memory debugger, whose site is down, without reliable fallback links
# https://elinux.org/Electric_Fence
#
# --enable-x11 (_HAVE_X11_) is not used
# --enable-doc is not used
# we don't need binreloc in distro package (or do we?..)
# portaudio support is broken in 2.2.0. Alsa or jack may be used instead.
src_configure() {
	econf \
		--enable-nls=$(usex nls) \
		--disable-guile_1_8 \
		--enable-guile_2_0=$(usex guile ) \
		--enable-jack=$(usex jack) \
		--enable-evince=$(usex evince) \
		--enable-aubio=$(usex aubio) \
		--enable-gtk$(usex gtk2 2 3) \
		--enable-alsa=$(usex alsa) \
		--enable-fluidsynth=$(usex fluidsynth) \
		--enable-rubberband=$(usex rubberband) \
		--enable-portmidi=$(usex portmidi) \
		--disable-portaudio \
		--enable-gtk-doc=$(usex doc) \
		--enable-gtk-doc-html=$(usex doc) \
		--enable-gcov=$(usex coverage) \
		--enable-always-build-tests=$(usex test) \
		--enable-installed-tests=$(usex test) \
		--enable-debug=$(usex debug) \
		--enable-static=$(usex static-libs) \
		--disable-mem \
		--disable-binreloc
}

pkg_postinst() { fdo-mime_desktop_database_update; }
pkg_postrm() { fdo-mime_desktop_database_update; }