# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6
inherit cmake-utils gnome2 versionator

SDK_PV=$(get_version_component_range 1-2)
SDK_PV=${SDK_PV//./}

DESCRIPTION="Multiplayer FPS based on the QFusion engine (evolved from Quake 2)"
HOMEPAGE="http://www.warsow.net/"
SRC_URI="http://sebastian.network/${PN}/${PN}_${SDK_PV}_sdk.tar.gz
	http://sebastian.network/${PN}/${P}.tar.gz
	https://warsow.net/mirror/${P}.tar.gz
	http://sebastian.network/${PN}/data1_${SDK_PV}pure.pk3
	http://sebastian.network/${PN}/UIfix/data2_${SDK_PV}pure.pk3
	mirror://gentoo/${PN}.png"

# ZLIB: bundled angelscript
LICENSE="GPL-2 ZLIB warsow"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND="
	media-libs/freetype
	media-libs/libogg
	media-libs/libpng:0
	media-libs/libsdl2[X,opengl,video]
	media-libs/libtheora
	media-libs/libvorbis
	media-libs/openal
	net-misc/curl
	sys-libs/zlib
	virtual/jpeg:0
	virtual/opengl"
DEPEND="${RDEPEND}"

S=${WORKDIR}/${PN}_${SDK_PV}_sdk/source/source
DATA_S=${WORKDIR}/${P}

src_prepare() {
	cmake-utils_src_prepare
}

src_configure() {
	local mycmakeargs=(
		-DQFUSION_GAME="Warsow"
	)

	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile
}

src_install() {
	dobin_wrapper() {
		local f

		for f in $@ ; do
			cat <<-EOF > "${T}/${f}" || die
			#!/bin/sh

			basepath="/usr/share/${PN}"

			cd "\${basepath}"

			exec "/usr/libexec/${PN}/${f}" \
				+set fs_basepath \${basepath} \
				+set fs_usehomedir 1 "\$@"
			EOF

			dobin "${T}/${f}"
		done
	}
	insinto /usr/share/${PN}
	doins -r "${DATA_S}"/basewsw
	insinto /usr/share/${PN}/basewsw
	doins "${DISTDIR}/data1_${SDK_PV}pure.pk3"
	doins "${DISTDIR}/data2_${SDK_PV}pure.pk3"

	cd build || die

	exeinto /usr/libexec/${PN}/
	doexe */*.so
	newexe ${PN}.* ${PN}
	newexe wsw_server.* ${PN}-ded
	newexe wswtv_server.* ${PN}-tv
	dobin_wrapper ${PN} ${PN}-ded ${PN}-tv

	dodir /usr/share/${PN}/libs
	local so
	for so in libs/*.so basewsw/*.so ; do
		dosym ../../../libexec/${PN}/${so##*/} /usr/share/${PN}/${so}
	done

	doicon -s 48 "${DISTDIR}"/${PN}.png
	make_desktop_entry ${PN} Warsow
}