[patch] testdisk-7.1_pre20180317.ebuild.patch

testdisk-7.1_pre20180317.ebuild.patch (text/plain), 3.93 KB, created by Andreas Sturmlechner on 2018-03-17 13:16:12 UTC

--- testdisk-7.0-r3.ebuild	2018-02-15 16:42:58.721725866 +0100
+++ testdisk-7.1_pre20180317.ebuild	2018-03-17 14:13:24.712199566 +0100
@@ -1,74 +1,82 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
+EAPI=6
 
-AUTOTOOLS_AUTORECONF=1
-
-inherit autotools-utils eutils flag-o-matic
+COMMIT=37b48a9fd645d38ab50bb33066acdaf868529d95
+inherit autotools flag-o-matic
 
 DESCRIPTION="Checks and undeletes partitions + PhotoRec, signature based recovery tool"
-HOMEPAGE="http://www.cgsecurity.org/wiki/TestDisk"
-SRC_URI="http://www.cgsecurity.org/${P}.tar.bz2"
+HOMEPAGE="https://www.cgsecurity.org/wiki/TestDisk"
+SRC_URI="https://git.cgsecurity.org/cgit/${PN}/snapshot/${PN}-${COMMIT}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS="amd64 ~arm ~hppa ppc x86"
-IUSE="ewf jpeg ntfs reiserfs static qt4"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~x86"
+IUSE="ewf jpeg ntfs qt5 reiserfs static zlib"
 
-REQUIRED_USE="static? ( !qt4 )"
+REQUIRED_USE="static? ( !qt5 )"
 
 # WARNING: reiserfs support does NOT work with reiserfsprogs
 # you MUST use progsreiserfs-0.3.1_rc8 (the last version ever released).
-DEPEND="
-		static? (
-			sys-apps/util-linux[static-libs]
-			>=sys-libs/ncurses-5.2:0[static-libs]
-			jpeg? ( virtual/jpeg:0[static-libs] )
-			ntfs? ( sys-fs/ntfs3g[static-libs] )
-			reiserfs? ( >=sys-fs/progsreiserfs-0.3.1_rc8[static-libs] )
-			>=sys-fs/e2fsprogs-1.35[static-libs]
-			sys-libs/zlib[static-libs]
-			!arm? ( ewf? ( app-forensics/libewf:=[static-libs] ) )
-			)
-		!static? (
-			sys-apps/util-linux
-			>=sys-libs/ncurses-5.2:0=
-			jpeg? ( virtual/jpeg:0 )
-			ntfs? ( sys-fs/ntfs3g )
-			reiserfs? ( >=sys-fs/progsreiserfs-0.3.1_rc8 )
-			>=sys-fs/e2fsprogs-1.35
-			sys-libs/zlib
-			!arm? ( ewf? ( app-forensics/libewf:= ) )
-			qt4? ( dev-qt/qtgui:4 )
-			)"
-RDEPEND="!static? ( ${DEPEND} )"
+COMMON_DEPEND="
+	static? (
+		sys-apps/util-linux[static-libs]
+		sys-fs/e2fsprogs[static-libs]
+		sys-libs/ncurses:0[static-libs]
+		jpeg? ( virtual/jpeg:0[static-libs] )
+		ntfs? ( sys-fs/ntfs3g[static-libs] )
+		reiserfs? ( >=sys-fs/progsreiserfs-0.3.1_rc8[static-libs] )
+		zlib? ( sys-libs/zlib[static-libs] )
+		!arm? ( ewf? ( app-forensics/libewf:=[static-libs] ) )
+	)
+	!static? (
+		sys-apps/util-linux
+		sys-fs/e2fsprogs
+		sys-libs/ncurses:0=
+		jpeg? ( virtual/jpeg:0 )
+		ntfs? ( sys-fs/ntfs3g )
+		qt5? (
+			dev-qt/qtcore:5
+			dev-qt/qtgui:5
+			dev-qt/qtwidgets:5
+		)
+		reiserfs? ( >=sys-fs/progsreiserfs-0.3.1_rc8 )
+		zlib? ( sys-libs/zlib )
+		!arm? ( ewf? ( app-forensics/libewf:= ) )
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	qt5? ( dev-qt/linguist-tools:5 )
+"
+RDEPEND="!static? ( ${COMMON_DEPEND} )"
 
-AUTOTOOLS_IN_SOURCE_BUILD=1
 DOCS=( )
 
-PATCHES=( "${FILESDIR}/${P}-qtbindir.patch" )
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+src_prepare() {
+	default
+	eautoreconf
+}
 
 src_configure() {
-	local myconf
+	local myeconfargs=(
+		--enable-sudo
+		$(use_with ewf)
+		$(use_with jpeg)
+		$(use_with ntfs)
+		$(use_with ntfs ntfs3g)
+		$(use_enable qt5 qt)
+		$(use_with reiserfs)
+		$(use_with zlib)
+	)
 
-	# this is static method is the same used by upstream for their 'static' make
+	# this static method is the same used by upstream for their 'static' make
 	# target, but better, as it doesn't break.
 	use static && append-ldflags -static
 
-	# --with-foo are broken, any use of --with/--without disable the
-	# functionality.
-	# The following variation must be used.
-	use reiserfs || myconf+=" --without-reiserfs"
-	use ntfs || myconf+=" --without-ntfs --without-ntfs3g"
-	use jpeg || myconf+=" --without-jpeg"
-	use ewf || myconf+=" --without-ewf"
-	myconf+=$(usex qt4 " --enable-qt" " --disable-qt")
-
-	econf \
-		--docdir "${ROOT}/usr/share/doc/${P}" \
-		--enable-sudo \
-		${myconf}
+	econf "${myeconfargs[@]}"
 
 	# perform safety checks for NTFS, REISERFS and JPEG
 	if use ntfs && ! egrep -q '^#define HAVE_LIBNTFS(3G)? 1$' "${S}"/config.h ; then