# Copyright 1994-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit java-pkg

DESCRIPTION="Avalon Framework"
HOMEPAGE="http://avalon.apache.org/"
SRC_URI="mirror://apache/avalon/avalon-framework/source/${PF}.src.tar.gz"
KEYWORDS="~x86"
LICENSE="Apache-2.0"
SLOT="0"

IUSE="doc jikes"
DEPEND=">=virtual/jdk-1.4
		>=dev-java/log4j-1.2.9
		>=dev-java/ant-core-1.5
		>=dev-java/avalon-logkit-1.2
		jikes? ( >=dev-java/jikes-1.21 )"
RDEPEND="${DEPEND}"

S=${WORKDIR}/${PN}
src_unpack() {
	unpack ${A}
	cd ${S}

	cp ${FILESDIR}/build.xml . || die "ANT update failure!"
	
	local libs="log4j,avalon-logkit"
	echo "classpath=`java-config -p ${libs}`" > build.properties
}

src_compile() {
	local antflags="jar"

	use jikes && antflags="${antflags} -Dbuild.compiler=jikes"
	use doc && antflags="${antflags} javadoc"

	ant ${antflags} || die "Compile failed!"
}

src_install() {
	java-pkg_dojar ${S}/dist/avalon-framework.jar
	dodoc LICENSE.txt NOTICE.TXT
	use doc && java-pkg_dohtml -r ${S}/dist/docs/*
}